在mathematica中选择特定的符号定义（不是转换规则）

Question

我有以下问题。

f[1]=1;
f[2]=2;
f[_]:=0;

dvs = DownValues[f];

这给了

dvs = 
   {
      HoldPattern[f[1]] :> 1, 
      HoldPattern[f[2]] :> 2, 
      HoldPattern[f[_]] :> 0
   }

我的问题是我只想提取 f[1] 和 f[2] 等的定义，而不是一般定义 f[_]，我不知道该怎么做。

我试过了，

Cases[dvs, HoldPattern[ f[_Integer] :> _ ]] (*)

但它什么也没给我，即空列表。

有趣的是，将 HoldPattern 更改为临时^footnote

dvs1 = {temporary[1] :> 1, temporary[2] :> 2, temporary[_] :> 0}

发行

Cases[dvs1, HoldPattern[temporary[_Integer] :> _]] 

给予

{temporary[1] :> 1, temporary[2] :> 2}

它有效。这意味着 (*) 几乎是一个解决方案。

我不明白为什么它适用于临时而不适用于 HoldPattern？如何让它直接与 HoldPattern 一起工作？

当然，问题是评估什么，不评估什么等等。在 Mathematica 中编码时的以太问题。真正的大师的东西......

致以最诚挚的问候 卓然

footnote = 我手动输入它作为替换“/. HoldPattern ->temporary”实际上执行了 f[_]:=0 规则并给出了一些奇怪的东西，我当然想避免这种执行。

Answer 1

原因是你必须转义HoldPattern，也许是Verbatim：

In[11]:= Cases[dvs, 
            Verbatim[RuleDelayed][
               Verbatim[HoldPattern][HoldPattern[f[_Integer]]], _]]

Out[11]= {HoldPattern[f[1]] :> 1, HoldPattern[f[2]] :> 2}

只有少数几个头需要这样做，HoldPattern 就是其中之一，正是因为它通常对模式匹配器“不可见”。对于您的temporary 或其他负责人，这不是必需的。注意模式f[_Integer] 被包裹在HoldPattern 中——这次HoldPattern 用于其直接目的——保护模式不被评估。请注意，RuleDelayed 也包含在 Verbatim 中 - 这实际上是 Verbatim 的另一个常见情况 - 这是必需的，因为 Cases 有一个涉及规则的语法，我们不希望 Cases 使用它解释在这里。所以，这是 IMO 一个很好的例子来说明HoldPattern 和Verbatim。 另请注意，使用HoldPattern 完全可以实现目标，如下所示：

In[14]:= Cases[dvs,HoldPattern[HoldPattern[HoldPattern][f[_Integer]]:>_]]

Out[14]= {HoldPattern[f[1]]:>1,HoldPattern[f[2]]:>2}

但是，将HoldPattern 用于转义目的（代替Verbatim）在IMO 概念上是错误的。

编辑

为了稍微说明Cases 的情况，这里有一个简单的例子，我们使用Cases 的语法涉及转换规则。这个扩展语法指示Cases 不仅要查找和收集匹配的片段，还要在找到它们之后立即根据规则对其进行转换，因此结果列表包含转换后的片段。

In[29]:= ClearAll[a, b, c, d, e, f];
Cases[{a, b, c, d, e, f}, s_Symbol :> s^2]

Out[30]= {a^2, b^2, c^2, d^2, e^2, f^2}

但是如果我们需要找到本身就是规则的元素呢？如果我们试试这个：

In[33]:= Cases[{a:>b,c:>d,e:>f},s_Symbol:>_]
Out[33]= {}

它不起作用，因为Cases 将第二个参数中的规则解释为使用扩展语法的指令，找到一个符号并将其替换为_。由于它默认搜索级别 1，并且符号在级别 2 上，因此它什么也找不到。观察：

In[34]:= Cases[{a:>b,c:>d,e:>f},s_Symbol:>_,{2}]
Out[34]= {_,_,_,_,_,_}

无论如何，这不是我们想要的。因此，我们必须强制Cases 将第二个参数视为普通模式（简单的，而不是扩展的语法）。有几种方法可以做到这一点，但它们都以某种方式“逃避”RuleDelayed（或Rule）：

In[37]:= Cases[{a:>b,c:>d,e:>f},(s_Symbol:>_):>s]
Out[37]= {a,c,e}

In[38]:= Cases[{a:>b,c:>d,e:>f},Verbatim[RuleDelayed][s_Symbol,_]:>s]
Out[38]= {a,c,e}

In[39]:= Cases[{a:>b,c:>d,e:>f},(Rule|RuleDelayed)[s_Symbol,_]:>s]
Out[39]= {a,c,e}

在所有情况下，我们要么避免Cases 的扩展语法（最后两个示例），要么设法利用它来发挥我们的优势（第一种情况）。

Answer 2

当然，Leonid 完全回答了为什么您的 temporary 解决方案有效但 HoldPattern 无效的问题。但是，作为对提取 f[1] 和 f[2] 类型术语的原始问题的答案，他的代码有点难看。为了解决提取这些术语的问题，我将只关注定义左侧的结构，并使用FreeQ 搜索所有级别的事实。所以，定义

f[1] = 1;  f[2] = 2;  f[_] := 0;
dvs = DownValues[f];

以下所有

Select[dvs, FreeQ[#, Verbatim[_]] &]
Select[dvs, FreeQ[#, Verbatim[f[_]]] &]
Select[dvs, ! FreeQ[#, HoldPattern[f[_Integer]]] &]

产生结果

{HoldPattern[f[1]] :> 1, HoldPattern[f[2]] :> 2}

如果在 f 的下限值的右侧没有 f[...]（或者，对于第一个版本，Blank[]）术语，那么上述其中一个可能是合适的。

Answer 3

基于西蒙的优秀解决方案here，我建议：

Cases[DownValues[f], _?(FreeQ[#[[1]], Pattern | Blank] &)]