WReach 为here 提供了一种使用OpenerView 表示Mathematica 评估序列的好方法。它比使用标准的Trace 或TracePrint 命令更清晰。但它还可以进一步改进。
我需要直接的方式来表示 Mathematica 的初学者主循环中的（子）评估的真实序列。特别是，新的求值子序列何时开始以及从哪个表达式开始应该很明显（最好将每个子序列精确地放在一个Opener 中）。应使用the standard evaluation sequence 尽可能轻松地识别评估（子）序列。我的意思是读者应该能够将真正的评估步骤映射到the standard evaluation sequence 的文档中描述的步骤。
有可能吗？
【问题讨论】：
citedOpenerView 解决方案使用Trace / TraceOriginal 生成其内容。这允许在该响应中简洁地定义show 的定义，但具有丢弃一些跟踪信息的缺点。 TraceScan 提供更多信息，因为它在每次评估的开始和结束时调用用户指定的函数。
下面定义了两个函数，它们尝试将TraceScan 信息格式化为（有点）可读的形式。
traceView2 显示评估时的每个表达式，以及导致该评估结果的子评估（“步骤”）。 “向下钻取”由OpenerView 提供。该函数生成如下所示的输出：
traceView2[(a + 1) + 2]
随着视图的深入，它会迅速从页面的右侧爬出。 traceView4 提供了一种替代视图，该视图不显示爬行行为，但代价是为任何给定评估显示更少的上下文：
选择你的毒药；）
函数的定义如下...
ClearAll@traceView2
traceView2[expr_] :=
Module[{steps = {}, stack = {}, pre, post, show, dynamic},
pre[e_] := (stack = {steps, stack}; steps = {})
; post[e_, r_] :=
( steps = First@stack ~Join~ {show[e, HoldForm[r], steps]}
; stack = stack[[2]]
)
; SetAttributes[post, HoldAllComplete]
; show[e_, r_, steps_] :=
Grid[
steps /. {
{} -> {{"Expr ", Row[{e, " ", Style["inert", {Italic, Small}]}]}}
, _ -> { {"Expr ", e}
, {"Steps", steps /.
{ {} -> Style["no definitions apply", Italic]
, _ :> OpenerView[{Length@steps, dynamic@Column[steps]}]}
}
, {"Result", r}
}
}
, Alignment -> Left
, Frame -> All
, Background -> {{LightCyan}, None}
]
; TraceScan[pre, expr, ___, post]
; Deploy @ Pane[steps[[1]] /. dynamic -> Dynamic, ImageSize -> 10000]
]
SetAttributes[traceView2, {HoldAllComplete}]
ClearAll@traceView4
traceView4[expr_] :=
Module[{steps = {}, stack = {}, pre, post},
pre[e_] := (stack = {steps, stack}; steps = {})
; post[e_, r_] :=
( steps = First@stack ~Join~ {{e, steps, HoldForm[r]}}
; stack = stack[[2]]
)
; SetAttributes[post, HoldAllComplete]
; TraceScan[pre, expr, ___, post]
; DynamicModule[{focus, show, substep, enter, exit}
, focus = steps
; substep[{e_, {}, _}, _] := {Null, e, Style["inert", {Italic, Small}]}
; substep[{e_, _, r_}, p_] :=
{ Button[Style["show", Small], enter[p]]
, e
, Style[Row[{"-> ", r}], Small]
}
; enter[{p_}] := PrependTo[focus, focus[[1, 2, p]]]
; exit[] := focus = Drop[focus, 1]
; show[{e_, s_, r_}] :=
Column[
{ Grid[
{ {"Expression", Column@Reverse@focus[[All, 1]]}
, { Column[
{ "Steps"
, focus /.
{ {_} :> Sequence[]
, _ :> Button["Back", exit[], ImageSize -> Automatic]
}
}
]
, Grid[MapIndexed[substep, s], Alignment -> Left]
}
, {"Result", Column@focus[[All, 3]]}
}
, Alignment -> Left, Frame -> All, Background -> {{LightCyan}}
]
}
]
; Dynamic @ show @ focus[[1]]
]
]
SetAttributes[traceView4, {HoldAllComplete}]
【讨论】：
Trace* 命令完全松散的一件事是应用Orderless 属性。在应用Orderless 属性后，我很惊讶地发现Plus[a, 1] 确实以Plus[1, a] 的形式再次评估！这似乎与the standard evaluation sequence 的描述相矛盾。
traceView2 的末尾应用Dynamic，将每个dynamic 替换为Dynamic？出于性能原因？
dynamic 替换是不必要的——它是该函数先前版本的剩余代码。它甚至可以被认为是有害的，因为最好推迟内部OpenerViews 的创建。我会修复它，但我注意到这些函数现在在我编写此响应后发布的 Mathematica 版本中的复杂跟踪性能非常差。似乎一些相关的性能特征在后来的 V7 微修订版（可能是 V7.0.1）中发生了变化。这些功能需要重新审视（但我现在不能这样做）。
只是对 WReach 非常有用的 traceView 功能的更新：更紧凑的视图，用于打开/折叠层次结构的更大按钮，以及保存按钮状态。
ClearAll[traceViewCompact];
SetAttributes[traceViewCompact, {HoldAllComplete}];
traceViewCompact[expr_] :=
Module[{steps = {}, stack = {}, pre, post, show, default = False},
pre[e_] := (stack = {steps, stack}; steps = {});
post[e_,
r_] := (steps = First@stack~Join~{show[e, HoldForm@r, steps]};
stack = stack[[2]]);
SetAttributes[post, HoldAllComplete];
show[e_, r_, steps_] := Module[{open = False},
Grid[
steps /. {{} -> {{"Expr ",
Item[e, Background -> GrayLevel@.8]}}, _ -> {{"Expr ",
e}, {Toggler[
Dynamic@
open, {True ->
Button["Steps", Appearance -> {"DialogBox", "Pressed"}],
False -> Button@"Steps"}],
steps /. {{} -> Style["no definitions apply", Italic], _ :>
Dynamic@
If[open, Column@steps,
Grid@{{Length@steps, "steps"}}]}}, {"Result", r}}},
Alignment -> {Left, Center}, Frame -> All,
Spacings -> Automatic, Background -> {{Hue[.65, .1, 1]}, None}]
];
TraceScan[pre, expr, ___, post];
Deploy@Column@{
Opener@Dynamic@default,
Dynamic@Pane[First@steps, ImageSize -> 10000]
}];
traceViewCompact[(a + 1) + 2]
【讨论】：
traceView 在 v10.3 中是否可以正常工作？如果是这样，我建议使用它，因为我很遗憾没有时间调试调试器。可能是一个非常递归的问题:)
这是我的方法，也是基于 WReach 的 OpenerView 技术。它的布局比他的 traceView2 紧凑得多，虽然不那么明确，而且据我所知，唯一牺牲的信息是显示隐藏在每个 OpenerView 中的步数。评估未更改的表达式由禁用的 OpenerView 指示，尽管我制作的屏幕截图没有显示禁用和启用的 OpenerView 之间的区别。
SetAttributes[TraceView, HoldFirst]
TraceView[e_, s___, opts : OptionsPattern[Trace]] :=
Module[{show2},
show2[{expr_, steps__}] :=
OpenerView[{expr, Column[show2 /@ {steps}]}];
show2[{HoldForm[x_]}] := Row[{Opener[True, Enabled -> False], HoldForm[x]}];
show2[HoldForm[x_]] := HoldForm[x];
show2[Trace[Unevaluated[e], s, opts, TraceOriginal -> True]]
]
【讨论】：
TraceScan 和 Trace 与 TraceOriginal -> True 的输出略有不同。在第二种情况下，(a+1) 的评估链在步骤“1+a”之前显示了附加步骤“a+1”。我不明白这个额外的步骤代表什么。有人有什么想法吗？
这是 joebolte 的 TraceView 的另一个实现，使用 12.3 中的新 Tree 功能：
SetAttributes[TraceView, HoldFirst];
TraceView[expr_] := Module[{trace, f, h, tree},
trace = Trace[expr, TraceOriginal -> True];
f[steps_List] := Rest[steps];
f[step_] := {};
h[steps_List] := First[steps];
h[step_] := step;
tree = NestTree[f, trace, Infinity, h];
TreeOutline[tree]]
【讨论】：