计数细胞，复制400个细胞，更新细胞总数，继续处理直到计数为0

Question

这是我想到的过程：

1. 计算 A 列中包含数据的所有单元格（我在想“xlUp”？）并将该数字设置为变量。
2. 选择 A 列中的前 400 个单元格（从 A2 开始），并将它们填充为黄色。
3. 复制该数据（数据被粘贴到另一个 prog（（我们称之为快捷键“！*Z”））。
4. 从总细胞计数变量中减去 400。
5. 在 A 列中选择第二个 400 个单元格（从 A402 开始）
6. 用黄色填充它们
7. 复制该数据 (!*Z)。
8. 从更新的细胞计数变量中减去 400。
9. 重复直到最后一个单元格的数据被复制并填充颜色。

任何帮助都会很棒。
我觉得我在这件事上绕圈子太久了。是时候问问专家了。谢谢！

Answer 1

批次范围

• 这是我对应用于您的案例的suggested post 的快速（简短）设想。如果您发现改进，请分享。

Option Explicit

Sub BatchRange()
    
    Const sfRow As Long = 2
    Const sCol As String = "A"
    Const Batch As Long = 400
 
    ' Create a reference to the First Cell.
    Dim sfCell As Range: Set sfCell = Sheet1.Cells(sfRow, sCol)
    ' Calculate the last row.
    Dim slRow As Long
    slRow = Sheet1.Cells(Sheet1.Rows.Count, sCol).End(xlUp).Row
    
    Dim srCount As Long: srCount = slRow - sfRow + 1
    Dim bCount As Long: bCount = Int(srCount / Batch) + 1
    
    Dim srg As Range
    Dim b As Long
    Dim r As Long
    
    For b = 1 To bCount
        
        If b = bCount Then
            r = srCount Mod Batch
        Else
            r = Batch
        End If
        
        If r > 0 Then
            ' Create a reference to the current Column Range.
            Set srg = sfCell.Resize(r)
            
            
            ' Do your stuff
            ' e.g.:
            Debug.Print sfCell.Address(0, 0), srg.Address(0, 0)
            ' or:
            srg.Interior.Color = vbYellow
            
            
            ' Create a reference to the next First Cell.
            Set sfCell = sfCell.Offset(r)
        End If
    
    Next b
    
End Sub