SET /p 在 If 语句中（批处理）

Question

我正在编写一个批处理文件来自动执行一些故障排除步骤。首先，我想确定用户是否在其 Internet Explorer 浏览器上启用了“保护模式”。如果他们这样做，我想提示他们将其关闭。我正在通过系统注册表执行此操作。

我确信注册表项是正确的，因为我已将值从 0 更改为 3，并且它的行为符合我的预期，在 Internet Explorer 中切换 Internet 区域的“保护模式”设置。

这是当前代码：

@echo off
Setlocal EnableDelayedExpansion

REM Check protected mode
echo Checking Internet Explorer settings
set "regCmd=reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3" /v 2500"
for /f "usebackq tokens=3* delims=   " %%a in (`!regCmd!`) do (
  set /a ProtectedMode=%%a
 )

if !ProtectedMode! == 0 (
    echo Protected mode in Internet Explorer is enabled.  It is recommended that protected mode be disabled in Internet Explorer.
    echo.
    set /P b_disable="Would you like to disable protected mode in Internet Explorer? (y/n)"
)
REM Checking to see that b_disable is set appropriately, it is
echo !b_disable!
REM Update protected mode to turn it off
if !b_disable!=="y" (
    echo Protected mode for Internet Explorer disabled.
)
if !b_disable!=="n" (
    echo Protected mode for Internet Explorer was NOT disabled.
)
pause

当我确实启用了保护模式时，当前的输出是：

检查 Internet Explorer 设置

Internet Explorer 中的保护模式已启用。推荐 在 Internet Explorer 中禁用保护模式。

您想禁用 Internet Explorer 中的保护模式吗(y/n)y

是的

按任意键继续。 . .

所以问题是 if 语句似乎没有被评估。我需要知道如何有条件地执行操作（如果用户按 y，我计划实现代码来更新同一键的注册表值）。

我了解了SetLocal 和EnableDelayedExpansion 以及使用!variable! 来引用来自another similar question 的设置变量

这是我的第一个批处理文件，对我来说都是全新的。当然，简单地告诉用户进入 IE 并取消选中“启用保护模式”会更容易，但任务是自动化它，同时允许用户进行一些控制（因此出现 y/n 提示）。

Answer 1

请注意，您要检查的注册表可能不存在。 仅当 !ProtectedMode! 时才需要检查用户输入！ == 0

@echo off
setlocal enabledelayedexpansion

for /f "tokens=3" %%a in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3" /v 2500 2^>nul ^| find "REG_DWORD" 2^>nul') do (
    set /a ProtectedMode=%%a
)
echo ProtectedMode=!ProtectedMode!

if !ProtectedMode! == 0 (
    echo Protected mode in Internet Explorer is enabled.  It is recommended that protected mode be disabled in Internet Explorer.
    echo.
    set /P b_disable="Would you like to disable protected mode in Internet Explorer? (y/n): "
    REM Checking to see that b_disable is set appropriately, it is
    echo !b_disable!
    REM Update protected mode to turn it off
    if "!b_disable!"=="y" (
        echo Protected mode for Internet Explorer disabled.
    )
    if "!b_disable!"=="n" (
        echo Protected mode for Internet Explorer was NOT disabled.
    )
)
pause