批处理 IF 语句块语法答案

【问题标题】：Batch IF Statement Block Syntax批处理 IF 语句块语法
【发布时间】：2022-01-11 07:04:09
【问题描述】：

我有以下代码（批量）来测试不工作的较大代码的一部分：

@echo off
set /a slotted55=8
set /a place=55
set /a key3=8
set /a key1=0
set /a key2=0
set /a key4=0
set /a key5=0
set /a key6=0
set /a strike=0
 if %place%==55 (
    if %key1%==%slotted55% (
        set key1=V
        set slotted55=V
        goto 5x5one
    ) else (
        if %key2%==%slotted55% (
            set key2=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        if %key3%==%slotted55% (
            set key3=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        if %key4%==%slotted55% (
            set key4=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        if %key5%==%slotted55% (
            set key5=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        if %key6%==%slotted55% (
            set key6=V
            set slotted55=V
            goto 5x5one
        )
    ) else (
        set /a strike=%strike% +1
        if %strike%==3 goto gameover
        set %slotted55%=X
        goto 5x5one
    )
 )
:gameover
echo gameover
pause
exit
:5x5one
echo good
pause

由于某种原因，它一直在崩溃。我查看了其他多个问题，但似乎没有一个适合这种情况。所有变量看起来都是正确的，并且没有丢失的操作数，但它不像批处理给你一个错误消息。谁能帮帮我？

【问题讨论】：

您根本不需要任何else 语句。

标签： if-statement batch-file syntax

【解决方案1】：

正如我在评论中所说，您不需要任何else 语句，而且您的开头if 语句没有else，您应该从使用相反的比较开始，因此没有所有内容都嵌套在一组括号中。

@Echo Off
SetLocal EnableExtensions
Set "place=55"
Set /A "key3=slotted55=8"
Set /A "key1=key2=key4=key5=key6=strike=0"

If "%place%" NEq "55" GoTo gameover

If "%key1%" == "%slotted55%" (
    Set "key1=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key2%" == "%slotted55%" (
    Set "key2=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key3%" == "%slotted55%" (
    Set "key3=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key4%" == "%slotted55%" (
    Set "key4=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key5%" == "%slotted55%" (
    Set "key5=V"
    Set "slotted55=V"
    GoTo 5x5one
)
If "%key6%" == "%slotted55%" (
    Set "key6=V"
    Set "slotted55=V"
    GoTo 5x5one
)
Set /A strike += 1
If %strike% Equ 3 GoTo gameover
Set "slotted55=X"
GoTo 5x5one

:gameover
Echo gameover
Pause
Exit /B

:5x5one
Echo good
Pause

【讨论】：

谢谢！这真的很有帮助！

【解决方案2】：

由于您将)s 放在哪里，您的所有else 语句都在相互查看，而不是您编写的其他if 语句。现在，你的逻辑看起来像这样：

if "%x%"=="5" (
    echo X is 5
) else (
    echo X is not 5
) else (
    echo X is somehow neither 5 nor is it not 5
)

如果您将您的else 与下一个if 结合起来，您的逻辑又是有意义的。

set /a strike=0
if %place%==55 (
    if %key1%==%slotted55% (
        set key1=V
        set slotted55=V
        goto 5x5one
    ) else if %key2%==%slotted55% (
        set key2=V
        set slotted55=V
        goto 5x5one
    ) else if %key3%==%slotted55% (
        set key3=V
        set slotted55=V
        goto 5x5one
    ) else if %key4%==%slotted55% (
        set key4=V
        set slotted55=V
        goto 5x5one
    ) else if %key5%==%slotted55% (
        set key5=V
        set slotted55=V
        goto 5x5one
    ) else if %key6%==%slotted55% (
        set key6=V
        set slotted55=V
        goto 5x5one
    ) else (
        set /a strike=%strike% +1
        if %strike%==3 goto gameover
        set %slotted55%=X
        goto 5x5one
    )
)

【讨论】：

【解决方案3】：

您在这里使用递增的数字，您可以只使用 for 循环并在 for 循环中使用一个 if 语句：

@echo off
setlocal enabledelayedexpansion

set /a slotted55=8, place=55, key3=8, key1=0, key2=0, key4=0, key5=0, key6=0, strike=0
if %place% neq %slotted55% goto :gameover
for /L %%i in (1,1,6) do (
       if !key%%i! equ %slotted55% (
            set "key%%i=V"
            set "slotted55=V"
            goto :5x5one
    ) 
)
:gameover
set /a strike+=1
if %strike% equ 3 (
    echo gameover
    pause
    exit
)
set "slotted55=X"

:5x5one
echo good
pause

现在，这里似乎缺少一些东西，除非你有一个 goto 来返回循环，否则你永远不会到达 strike=3。因此，如果没有所有 else 语句，此代码将像您的代码一样工作。

【讨论】：