使用for循环和变量替换批量拆分文件路径

Question

我已经搜索了很长一段时间，但没有让我的脚本正常工作。我觉得我很接近，但需要一点帮助。我正在尝试使用 FOR 循环递归扫描“srcdir”（在我的脚本开头设置），然后一旦循环返回文件/路径（%%f），然后我可以用其他东西替换文件路径的一部分（例如：C:\rootpath\src 代表 C:\rootpath\des）。

我可以通过使用这样的脚本来做这样的事情：

set subdir=C:\rootpath\src
set subdir=%subdir:src=des%
echo %subdir%

然而，让这变得困难的是，我的“srcdir”的根路径可能会改变（例如，C:\roothpath）并且“srcdir”之后的所有递归都可能会改变（例如，C 中文件夹“src”之后的任何内容:\rootpath\src)。文件夹 src 和文件夹 des 的唯一常量路径（位于我运行批处理文件的同一目录中）。

因此，通过使用前面示例中的相同技术，我想使用 FOR 循环递归地查找“srcdir”（%%f）中文件的完整路径，并将文件夹“src”替换为文件夹路径字符串中的“des”。因此，我尝试将“%%f”设置为变量（子目录）并使用变量替换替换文件夹。

这是我当前无法运行的脚本：

set srcdir=C:\rootpath\src
for /r "%srcdir%" %%f in (*.txt) do (
set subdir=%%f
set subdir=%subdir:src=des%
echo %subdir%
)

任何帮助将不胜感激！谢谢！

Answer 1

您需要启用delayed expansion，因为您正在像for 循环这样的代码块中分配和读取变量：

setlocal EnableDelayedExpansion
set "srcdir=C:\rootpath\src"
for /R "%srcdir%" %%F in ("*.txt") do (
    set "subdir=%%~fF"
    set "subdir=!subdir:\src\=\des\!"
    echo(!subdir!
)
endlocal

setlocal EnableDelayedExpansion 命令启用延迟扩展；它还本地化环境，这意味着对环境变量的更改仅在执行endlocal 或终止批处理文件之前可用。

要实际使用延迟扩展，您需要将百分号替换为感叹号，因此%subdir% 变为!subdir!。