Perl：为什么这会创建数千个子进程？

Question

所以，当我运行这段代码时，它似乎对系统进行了分叉炸弹，你们能帮帮我吗？我要做的就是为每个 appWatch 域和环境启动一个线程。

#!/usr/bin/perl
#
#
#       Starts the mass processes to watch each directory & enviroment.
#
#
#
###################################################################################
use strict;
use warnings;
use POSIX 'setsid';
setsid();
my @domains = (qw(austin batman luke heman drevil joker skeltor drevil goodguy badguy));
my @envs = (qw(qa dev));
        foreach my $env (@envs){
                foreach my $guy (@domains){
                        unless(my $pid = fork()){
                                system("echo $env.$guy");
                                system("sleep 10 ");
                                #system("./appWatch -d $guy -e $env");
                                open PID, ">>pid.lock";
                                print PID $$ . "\n";
                                print "$$ is Parent, $pid is child";
                }
        }
}
                wait();

Answer 1

您的代码应该只创建三个孩子。如果您看到创建了一堆孩子，那么您正在运行不同的代码（或者罪魁祸首是 appWatch 而不是您的代码）。在一个稍微不相关的说明中，您可能应该做一些不同的事情：

1. fork 有三个可能的返回值，而不是两个
2. 你必须收割你的孩子或设置系统为你收割他们
3. 如果你不想返回代码，你应该使用exec而不是system
4. 如果您不希望 shell 处理参数，则应使用 system 和 exec 的多参数版本，而不是单参数版本。

这是我的代码版本：

$SIG{CHLD}  = "IGNORE"; #auto-reap the children
my @domains = qw(domains);
my @envs    = qw(enviromentA enviromentB);
for my $env (@envs){
        for my $guy (@domains){
                die "could not fork: $!" unless defined(my $pid = fork);
                next if $pid;
                exec "./appWatch", "-d", $guy, "-e", $env;
                die "exec must have failed";
        }
}

您更新的代码版本显示了发生的情况。您的孩子不会退出。以下是我将如何编写您的代码：

#!/usr/bin/perl
# Starts the mass processes to watch each directory & enviroment.

use strict;
use warnings;
use POSIX 'setsid';
setsid();

my @domains = qw(
    austin  batman luke    heman
    drevil  joker  skeltor drevil
    goodguy badguy
);
my @envs = qw(qa dev);

my @pids;
for my $env (@envs){
    for my $guy (@domains){
        die "could not fork: $!" unless defined(my $pid = fork);
        if ($pid) {
            push @pids, $pid;
            next;
        }
        print "$env.$guy\n";
        sleep 10; #FIXME: I don't know if you really need this
        #exec will replace the child process with appWatch
        exec "./appWatch", "-d", $guy, "-e", $env;
        die "exec failed for some reason";
    }
}
for my $pid (@pids) {
    waitpid $pid, 0;
}

Answer 2

有

$ cat appWatch
#！ /usr/bin/perl -l
print "[", join("][" => @ARGV), "]";

正在运行

$ unname -a
Linux mybox 2.6.32-24-generic #39-Ubuntu SMP Wed Jul 28 05:14:15 UTC 2010 x86_64 GNU/Linux

我没有得到fork 炸弹，只是一个乏味的笛卡尔积：

$ ./prog.pl
[-d][域][-e][环境A]
[-d][域][-e][环境B]