使用 2 个其他变量在 SPSS 中创建一个变量？

Question

所以，我使用 SPSS 的时间不长，我需要帮助创建一个使用其他两个变量的变量。

我有一个调查，每个人的“家庭人数”变量和“与户主的关系”的另一个变量（户主=1，配偶=2，孩子=3等）。 我想通过每个家庭与户主的关系来创建一个“家庭类型”的变量。

所以，类似：

If in the household there's only the head, then is 1
If there's the head, spouse and/or children, then is 2
If it's head plus any other type of relative, it's 3.

例如：

家庭编号 - 关系

1 - 1

1 - 2

1 - 3

在家庭“1”中有一个户主（1），一个配偶（2）和一个孩子（3），所以它是一个“家庭类型”2。

我不知道用于执行此操作的命令是 SPPS。谁能帮帮我？

Answer 1

我怀疑这将需要使用AGGREGATE 将所需的特征分配给所有家庭成员，然后使用 if 语句来制作家庭类型。因此，让我们从一些类似于您的示例数据开始。这会生成一组长格式的族。

data list free / house relation.
begin data
1 1
1 2
1 3
2 1
3 1
3 2
4 1
4 3
5 1
5 2
5 3
5 3
5 3
end data.
VALUE LABELS relation
1 'Head'
2 'Spouse'
3 'Child'.

从这里我将推荐四种类型的家庭； Single-No Children、Couple-No Children、Single-With Children 和 Couple-With Children。为了得到这些，我创建了一个虚拟变量来表示一个案例是孩子还是配偶，然后聚合家庭内的最小值，以提供家庭是否有配偶或孩子的标志。

*Make flag for if have a spouse and if have a child.
COMPUTE child = (relation EQ 3).
COMPUTE spouse = (relation EQ 2).
*Aggregate to get a flag for child or spouse.
AGGREGATE
  /OUTFILE=* MODE=ADDVARIABLES
  /BREAK=house
  /AnyChild = MAX(child) 
  /AnySpouse = MAX(spouse)
  /NumChild=SUM(child)
  /TotalFamSize=N.

我还展示了如何在聚合命令中使用SUM 获取儿童总数，以及使用N 获取家庭总人数。从这里您可以使用一系列 if 语句来对不同类型的族进行分类。

*From here can make several fam categories using DO IF.
DO IF TotalFamSize = 1.
  COMPUTE FamType = 1.
ELSE IF AnySpouse = 1 AND AnyChild = 0.
  COMPUTE FamType = 2.
ELSE IF AnySpouse = 0 and AnyChild = 1.
  COMPUTE FamType = 3.
ELSE IF AnySpouse = 1 and AnyChild = 1.
  COMPUTE FamType = 4.
END IF.
VALUE LABELS FamType
1 'Single - No Children'
2 'Couple - No Children'
3 'Single - Children'
4 'Couple - Children'.
EXECUTE.

这种使用聚合来获取整个家庭的统计数据的逻辑应该适用于您想要生成的任何类型的统计数据。