从 EXEC 存储过程中选择特定列

Question

我在尝试从存储过程的 EXEC 语句中 SELECT 特定列时遇到问题。我正在尝试找到存储过程返回的COUNT(*)，我正在成功地使用它：

INSERT INTO #temp
EXEC dbo.my_sp
SET @count = (SELECT COUNT(*) FROM #temp)
DELETE FROM #temp

但是，这仅在返回的列与表列特别匹配时才有效，并且由于我试图查找许多不同存储过程的计数（每个存储过程返回不同的列），如果不创建新的列，我将无法使用此方法每个存储过程的表。

有没有办法可以SELECT EXEC dbo.my_sp 中的特定列？

Answer 1

创建到本地实例的环回链接服务器，确保启用数据访问。假设您有一个名为 YourServer\SQL2008 的本地命名实例：

USE [master];
GO
EXEC sp_addlinkedserver 
  @server     = N'LoopbackLocal', 
  @srvproduct = N'',
  @provider   = N'SQLNCLI', 
  @datasrc    = N'.\SQL2008', 
  @catalog    = N'tempdb';
GO

EXEC sp_serveroption 
  @server   = N'LoopbackLocal', 
  @optname  = N'collation compatible', 
  @optvalue = N'true';
GO

EXEC sp_serveroption 
  @server   = N'LoopbackLocal', 
  @optname  = N'data access', 
  @optvalue = N'true';
GO

EXEC sp_addlinkedsrvlogin 
  @rmtsrvname = N'LoopbackLocal', 
  @locallogin = NULL , 
  @useself    = N'True';
GO
-- you may need to configure other security here

然后您可以使用OPENQUERY 来运行存储过程，就好像它是一个即席查询一样。

SELECT COUNT(*)
  FROM OPENQUERY
  (
    LoopbackLocal, 
    'EXEC dbo.my_sp'
  ) AS y;

现在，如果dbo.my_sp 首先将信息转储到#temp 表中，您就会遇到问题，因为它不再是OPENQUERY 可以处理的代码块。例如，如果您尝试以这种方式执行 sp_who2，至少在 SQL Server 2012 中，您将收到来自 sp_describe_first_result_set 的错误，其中 OPENQUERY 已更改为使用（所以也许现在这对您有用，我不'没有 2008 年要测试，但总有一天会成为问题）：

消息 11526，级别 16，状态 1，过程 sp_describe_first_result_set，第 1 行
无法确定元数据，因为 ... 使用临时表。

但是，如果您要经常这样做，为什么不制作专门的存储过程（或向这些存储过程添加选项）以便只返回一个计数？

Answer 2

@@ROWCOUNT 对你有用吗？

if OBJECT_ID('SomeProc') is null
    exec ('create procedure dbo.SomeProc as select 1 as SomeValue union all select 2 as SomeValue;')

exec dbo.SomeProc

Select @@ROWCOUNT as RowsAffected

http://technet.microsoft.com/en-us/library/ms187316(v=sql.105).aspx