ReadConsoleInputA 引发访问冲突

Question

我正在尝试学习如何使用 windows api（而不仅仅是使用 C 调用、irvine32 或 masm32）并且遇到了 ReadConsoleInputA 的问题（WriteConsoleA 工作正常）。

另外，我不明白为什么在函数的 PROC 原型中，大多数示例在 ReadConsoleInput/WriteConsole 的末尾附加了 A 或 W，你能解释一下原因吗？

.data
consoleOutHandle dd ?
consoleInHandle dd ?
bufferlen dd ?
buffer db ?
bufferSize DWORD ?
message db "Enter a number:", 0
lmessage equ $-message


.code
main PROC

    invoke GetStdHandle, STD_OUTPUT_HANDLE
    mov consoleOutHandle, eax

    invoke ReadConsoleInputA, consoleOutHandle, offset buffer, 128, bufferSize
main endp
end main

它抛出：访问冲突写入位置0x00000004。

按照 Michael Petch 的建议，我现在有了以下代码：

.data
consoleOutHandle dd ?
consoleInHandle dd ?
byteswritten dd ?
bufferlen dd ?
buffer db 128 DUP(?)
bufferSize dd ?
message db "Enter a number:", 0
lmessage equ $-message


.code
main PROC
    invoke GetStdHandle, STD_INPUT_HANDLE
    mov consoleInHandle, eax
    invoke GetStdHandle, STD_OUTPUT_HANDLE
    mov consoleOutHandle, eax
    mov eax, lmessage
    invoke WriteConsoleA, consoleOutHandle, offset message, eax, bytesWritten, 0

    invoke ReadConsoleInputA, consoleInHandle, offset buffer, 128, offset bufferSize
main endp
end main

现在它抛出“触发断点”。

反汇编：

invoke ReadConsoleInputA, consoleInHandle, offset buffer, 128, offset bufferSize
00E71066  push        offset bufferSize (0E74090h)  
00E7106B  push        80h  
00E71070  push        offset buffer (0E74010h)  
00E71075  push        dword ptr [consoleInHandle (0E74004h)]  
00E7107B  call        _ReadConsoleInputA@16 (0E7100Ah)  
--- No source file -------------------------------------------------------------
00E71080  int         3    **---> Breakpoint here**
00E71081  int         3  

Answer 1

您询问了 WinAPI 函数末尾的 A 和 W 后缀的用途。以A 结尾的函数表示Ansi，以W 结尾的函数是Wide。微软以这种方式记录它们：

Unicode 和 ANSI 函数 当 Microsoft 将 Unicode 支持引入 Windows 时，它通过提供两组并行的 API 来简化转换，一组用于 ANSI 字符串，另一组用于 Unicode 字符串。例如，有两个函数可以设置窗口标题栏的文本：

• SetWindowTextA 采用 ANSI 字符串。
• SetWindowTextW 采用 Unicode 字符串。

---

在第一版代码中

• 您没有为buffer 分配必要的空间。你有：

  buffer db ?
  

  这为缓冲区分配了一个字节。应该是：

  buffer db 128 DUP(?)
  

• 您使用了STD_OUTPUT_HANDLE 而不是STD_INPUT_HANDLE

• ReadConsoleInputA 的最后一个参数是一个指向 DWORD 的指针，它将返回读取的事件数。更改变量名称bufferSize 可能会使代码更具可读性。来自ReadConsoleInputA 文档：

  BOOL WINAPI ReadConsoleInput(
   _In_  HANDLE        hConsoleInput,
   _Out_ PINPUT_RECORD lpBuffer,
   _In_  DWORD         nLength,
   _Out_ LPDWORD       lpNumberOfEventsRead
  );
  

• 如果您只读取键盘，您应该使用ReadConsoleA，因为ReadConsoleInputA 将处理键盘和鼠标事件，并且可能在读取您的字符串之前过早返回。 ReadConsoleA 多了一个参数，你可以设置为NULL：

  BOOL WINAPI ReadConsole(
   _In_     HANDLE  hConsoleInput,
   _Out_    LPVOID  lpBuffer,
   _In_     DWORD   nNumberOfCharsToRead,
   _Out_    LPDWORD lpNumberOfCharsRead,
   _In_opt_ LPVOID  pInputControl
  );
  

• 要退出程序，您需要调用ExitProcess。

---

在第二版代码中

• 您的代码可以：

  invoke WriteConsoleA, consoleOutHandle, offset message, eax, bytesWritten, 0
  

  bytesWritten 需要是一个指针，因为那是一个输出参数。来自WriteConsoleA 文档：

  BOOL WINAPI WriteConsole(
   _In_             HANDLE  hConsoleOutput,
   _In_       const VOID    *lpBuffer,
   _In_             DWORD   nNumberOfCharsToWrite,
   _Out_            LPDWORD lpNumberOfCharsWritten,
   _Reserved_       LPVOID  lpReserved
   );
  

---

根据您的第二个代码示例，使用ReadConsoleA 而不是ReadConsoleInputA 的代码版本可能如下所示：

.data
consoleOutHandle dd ?
consoleInHandle dd ?
bytesWritten dd ?
bufferlen dd ?
buffer db 128 DUP(?)
numEvents dd ?
message db "Enter a number:", 0
lmessage equ $-message

.code
main PROC
    invoke GetStdHandle, STD_INPUT_HANDLE
    mov consoleInHandle, eax
    invoke GetStdHandle, STD_OUTPUT_HANDLE
    mov consoleOutHandle, eax
    mov eax, lmessage
    invoke WriteConsoleA, consoleOutHandle, offset message, eax, offset bytesWritten, 0

    invoke ReadConsoleA, consoleInHandle, offset buffer, 128, offset numEvents, 0
    invoke ExitProcess, 0
main endp
end main

使用 MASM 的 sizeof 运算符可以稍微清理一下这段代码。代码可以写成：

.data
consoleOutHandle dd ?
consoleInHandle dd ?
buffer db 128 DUP(?)
bytesWritten dd ?
numEvents dd ?
message db "Enter a number:", 0

.code
main PROC
    invoke GetStdHandle, STD_INPUT_HANDLE
    mov consoleInHandle, eax
    invoke GetStdHandle, STD_OUTPUT_HANDLE
    mov consoleOutHandle, eax
    invoke WriteConsoleA, consoleOutHandle, offset message, sizeof message, offset bytesWritten, 0
    invoke ReadConsoleA, consoleInHandle, offset buffer, sizeof buffer, offset numEvents, 0
    invoke ExitProcess, 0
main endp
end main