从此语法中删除间接左递归

Question

我试图弄清楚如何从我的 Ruby 解析器 (https://github.com/kenaniah/ruby-parser/blob/master/ruby-parser/src/parsers/expression/logical.rs) 的 Rust 端口中的逻辑关键字表达式中删除间接左递归。语法如下：

E --> N | A | O | t
N --> n E
A --> E a E
O --> E o E

E = expression
A = keyword_and_expression
O = keyword_or_expression
N = keyword_not_expression

我将如何进行转换以删除 A 和 O 中的递归？

Answer 1

根据这个factorization tool，生成的语法将是：

E  -> N
    | A
    | O
    | t
N  -> n E
A  -> n E a E A'
    | O a E A'
    | t a E A'
O  -> n E o E O'
    | n E a E A' o E O'
    | t a E A' o E O'
    | t o E O'
A' -> a E A'
    | ϵ
O' -> a E A' o E O'
    | o E O'
    | ϵ

由于E 的多次产生，A 和 O 的因式分解最终变得相当复杂。

Answer 2

我认为这里的问题不是间接递归，而是歧义。

如果只是间接递归，你可以简单地替换N、A和O的右侧，消除间接递归：

E → n E
  | E a E
  | E o E
  | t

为了摆脱直接左递归，你可以left-factor：

E → n E
  | E A'
  | t
A'→ a E
  | o E

然后移除剩余的左递归：

E → n E E'
  | t E'
E'→ ε
  | A' E'
A'→ a E
  | o E

没有直接或间接的左递归，并且每条规则都以唯一的终端开始。但是，它不是 LL(1)，因为存在先/后冲突。

这并不奇怪，因为原来的语法是高度歧义的，左递归消除并不能消除歧义。原始语法只有在带有operator precedence table 时才真正有意义。

该表表明AND 和OR 是具有相同优先级的左结合运算符（一个有点不寻常的决定），而NOT 是具有更高优先级的一元运算符。反过来，这意味着 BNF 应该写成这样：

N → n N
  | t
E → A
  | O
  | N
A → E a N
O → E o N
N → n N
  | t

与 OP 中语法的唯一区别是消除了歧义，如优先表所示。

同样，第一步是替换非终结符 A 和 O 以使左递归直接：

E → E a N
  | E o N
  | N
N → n N
  | t

这与算术表达式的语法本质上是相同的语法（忽略乘法，因为只有一个优先级），并且可以直接消除左递归：

E  → N E'
E' → a E
   | o E
   | ε
N  → n N
   | t