统计表：使用 esttab，使用 xtreg 指示（）答案

【问题标题】：Stata tables: Using esttab, indicate() with xtreg统计表：使用 esttab，使用 xtreg 指示（）
【发布时间】：2013-09-30 08:31:27
【问题描述】：

有谁知道esttab 中的“indicate()”选项是否可以与xtreg 一起使用？如果我运行像

这样的回归

eststo MYREG: reg y x i.category,

那我就可以了

esttab MYREG , indicate("Category FE = *.category")

我会得到一张像这样的漂亮桌子：

----------------------
x            2.3443
             (2.15)
Category FE    Yes
----------------------
N             4321
----------------------

问题：当我使用

xtset category
xtreg y x

没有保存可以在指示语句中使用的系数。或者有吗？我一直找不到。

我意识到我可以使用

estadd local fe "Yes" : MYREG

然后我可以得到一个像

这样的表

esttab MYREG , stats(N fe)

----------------------
x            2.3443
             (2.15)
----------------------
N             4321
Category FE    Yes
----------------------

但我正在使用一堆其他“i.VAR”类型的固定效果，我希望它们全部一起显示在系数下方，而不是只有一个显示在页脚中。

【问题讨论】：

如果您解释说您使用的是均值差分面板估计器（xtreg..., fe 就是这样做的），则表明您对面板变量具有固定效应，因为固定效果已被区分而不是被虚拟化（就像在 reg ... i.category 中所做的那样），这与您想要作为对照 (i.VAR) 包含的其他固定效果向量不具有可比性。
您错了，使用“i.VAR”或“xtreg”会产生非常非常非常相似的结果......每组（家庭）有两个观察结果，它们实际上在数值上是相同的。所以是的，问题是存在的。
对，我的评论不是关于它们是否相同。从数学上讲，它们是。这是关于暗示有一个未显示的类别的系数向量（这是您对其他 i.VAR 固定效果所做的事情），而 xtreg YX ... ,fe.

标签： output stata effects

【解决方案1】：

最快的做法是使用varlist 选项插入任意行的文本/smcl/latex。例如，要在 _cons 之前插入一行注释 FE（而不是在统计面板中），请使用

esttab myreg, stats(N) varlabels(,blist(_cons "{p2col 0 20 0 0: FE}yes{p_end}"))

将显示的内容：

----------------------------
                      (1)   
                   weight   
----------------------------
week                6.210***
                 (158.97)   
FE                 yes
_cons               19.36***
                  (32.09)   
----------------------------
N                     432   
----------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001

您可以调整20 以获得正确的水平布局，或者只使用空格（如果您有多个模型，您会这样做。

如果您想要更健壮的东西（可以处理模型重新排序），另一种方法是编辑每个模型估计并将虚假条目放入 e(b)（和 e(V)）矩阵中，然后使用指示何时你输出表格。这是我用过的一个简单的ado：

*Needs erepost
program add_fake_coeff_to_e, eclass
    args cname cval

    tempname eb eb2 eV eV2
    mat `eb' = e(b)
    local eb_names : colnames `eb'
    mat `eb2' = `eb', `cval'
    matrix colnames `eb2' = `eb_names' `cname'

    *Need the dimensions of V to match b
    mat `eV' = e(V)
    local num_eb : word count `eb_names'

    mat `eV2' = I(`=`num_eb'+1')
    mat `eV2'[1,1] = `eV'
    matrix colnames `eV2' = `eb_names' `cname'
    matrix rownames `eV2' = `eb_names' `cname'

    erepost b=`eb2' V=`eV2'
end

那么你会这样做

reg blah
add_fake_coeff_to_e "FE" 1
estimates store est1
esttab est1 , <other opts> indicate("FE", labels("Y" ""))

【讨论】：