使用 esttab 格式化表格

Question

我能够创建我想要的大部分内容：两个单向表格（报告累积百分比）并排在同一张表中。这很好，但我需要一些格式化方面的帮助。一个玩具例子：

sysuse auto, clear
eststo clear
eststo a: estpost tabulate rep78 if foreign==0
eststo b: estpost tabulate rep78 if foreign==1
esttab, cells("cumpct(fmt(2))") ///
    varlabels("a" "b")      ///
    nonumber nomtitle noobs ///
    collabels("a" "b")

这会产生以下结果：

--------------------------------------
                        a            a
--------------------------------------
1                    4.17             
2                   20.83             
3                   77.08        14.29
4                   95.83        57.14
5                  100.00       100.00
Total                                 
--------------------------------------

我该怎么做：

1. 去掉总行和
2. 使列标签具有不同的名称？我希望将第二列称为b，而不是a。我尝试了 collabels 中内容的不同变体（a b、"a b"、""a" "b""），但似乎没有任何效果。

Answer 1

其中任何一个都可以解决问题：

sysuse auto, clear
eststo clear
qui eststo a: estpost tabulate rep78 if foreign==0
qui eststo b: estpost tabulate rep78 if foreign==1
esttab, cells("cumpct(fmt(2))") ///
    nonumber mtitles("a" "b") nodepvars noobs drop(Total) collabels(none)

eststo clear
qui eststo a, title("a"): estpost tabulate rep78 if foreign==0
qui eststo b, title("b"): estpost tabulate rep78 if foreign==1
esttab, cells("cumpct(fmt(2))") ///
    nonumber mtitles nodepvars noobs drop(Total) collabels(none)

我更喜欢第二种语法，因为我喜欢在我估计它们的位置附近命名模型。

两者都会产生如下所示的内容：

--------------------------------------
                        a            b
--------------------------------------
1                    4.17             
2                   20.83             
3                   77.08        14.29
4                   95.83        57.14
5                  100.00       100.00
--------------------------------------