拜托，我尝试创建一个复杂的数据结构。我知道该怎么做
$branch{'level1'}{'level2'}{'level3'}='leaf';
但我不知道如何创建
$branch{'level1'}....{'levelN'}='leaf';
我尝试这样的事情：
$branch{'leaf'} = "1";
$branchREF = \%branch;
$branchtmp{'level3'} = $branchREF;
所以我成功得到：
$VAR1 = 'level3';
$VAR2 = {
'leaf' => '1'
};
但是对于下一步，做一个递归的 N 哈希，我尝试：
%branch = %branchtmp;
但结果完全错误...%branch 不是我所期望的。为了进行递归，我需要重用我的第一个 %branch 而不是创建一个新的。请问我该怎么办？
一个。
【问题讨论】：
标签： perl data-structures
我强烈建议使用现有的解决方案，例如 Data::Diver。
use Data::Diver qw( DiveVal );
my @keys = map "level$_", 1 .. 3;
my $branch = {};
DiveVal($branch, map \$_, @keys) = 'leaf';
-or-
my %branch;
DiveVal(\%branch, map \$_, @keys) = 'leaf';
显然，它也可以在没有模块的情况下完成。
sub DiveVal :lvalue {
my $p = \shift;
$p = \( $$p->{$_} ) for @_;
$$p
}
my @keys = map "level$_", 1 .. 3;
my $branch;
DiveVal($branch, @keys) = 'leaf';
-or-
my %branch;
DiveVal(\%branch, @keys) = 'leaf';
我的DiveVal 是如何工作的：
Pre-loop: $p references $branch
After loop pass 0: $p references $branch->{level1}
After loop pass 1: $p references $branch->{level1}{level2}
After loop pass 2: $p references $branch->{level1}{level2}{level3}
Returned: $branch->{level1}{level2}{level3}
额外的间接层有很多好处。
DiveVal 以支持混合数组/哈希结构。【讨论】：
:lvalue。我需要它:)
Data::Diver可以帮你：
#!/usr/bin/perl
use warnings;
use strict;
use Data::Diver qw{ DiveVal };
use Data::Dumper;
my %branch;
DiveVal(\%branch, map "level$_", 1 .. 3) = 'leave';
print Dumper \%branch;
输出：
$VAR1 = {
'level1' => {
'level2' => {
'level3' => 'leave'
}
}
};
或者，如果你想自己实现它：
#!/usr/bin/perl
use warnings;
use strict;
use Data::Dumper;
sub set_value {
my ($struct, @list) = @_;
if (@list > 2) {
set_value($struct->{ $list[0] } = {}, @list[ 1 .. $#list ]);
} else {
$struct->{ $list[0] } = $list[1];
}
}
my %branch;
set_value(\%branch, map("level$_", 1 .. 3), 'leave');
print Dumper \%branch;
【讨论】：
最简单的方法是记住 perl 如何处理多维数据结构。它通过引用来做到这一点。因此，您可能会发现从顶层开始更简单，而不是作为哈希引用：
#!/usr/bin/env perl
use strict;
use warnings;
use Data::Dumper;
my @levels = qw ( level1 level2 level3 );
my $branch = {};
my $tail = pop(@levels);
my $cursor = $branch;
#iterate our levels
foreach my $level (@levels) {
#make a new anon-hash if there isn't one.
$cursor -> {$level} ||= {};
#traverse down
$cursor = $cursor->{$level};
}
#set a value
$cursor -> {$tail} = 'leaf';
print Dumper $branch;
输出：
$VAR1 = {
'level1' => {
'level2' => {
'level3' => 'leaf'
}
}
};
注意 - 您必须重置光标并“重新遍历”才能再次执行此操作，但可以以类似的方式“行走”结构。
【讨论】：
$cursor = ...; 替换为$cursor = \( ... ); 并调整$cursor 的所有其他实例，这可以大大简化。见我的answer。
一个简单的递归解决方案：
#!/usr/bin/env perl
use strict;
use warnings;
use Data::Dumper;
sub recursiveHash {
my ($result, @rest) = @_;
return $result unless @rest;
my $nextTag = pop @rest;
return recursiveHash( {$nextTag => $result}, @rest);
}
print Dumper(recursiveHash('leaf', 'level1', 'level2', 'level3'));
输出：
$VAR1 = {
'level1' => {
'level2' => {
'level3' => 'leaf'
}
}
};
也就是说，Perl 中的子程序调用相当慢。幸运的是，这里完全不需要递归。
sub iterativeHash {
my ($result, @rest) = @_;
while (@rest) {
my $nextTag = pop @rest;
$result = { $nextTag => $result };
}
return $result;
}
【讨论】：
DiveVal($root, @keys) = $leaf; 可以。
我使用 DBM::Deep，您可能必须自己安装它。我需要一些可以处理长键值和大约 100,000 个键的东西。普通 Perl 散列（默认安装的散列）仅处理 1008 字节的组合键和数据长度。
# LIMITS:
# - Key size limit: none
# - Data size limit: limited by OS
# - Number of keys per hash: millions
# - Number of nested levels: millions. "Can handle millions of keys and unlimited levels without significant slow-down. "
# Basic
use Fcntl; # Required for hashes.
use DBM::Deep;
my($db);
my $fn='file.dbm';
$db=DBM::Deep->new($fn) or die "Could not make DBM::Deep in file $fn";
$db->{'key1'}="stuff";
delete $db->{'key1'};
if ($db->exists("key"))
{
print "Yay\n";
}
$db->clear(); # Delete all keys.
@k=keys(%$db); # Get all first level keys.
# Alternate
my $fn='file.dbm';
tie my %db, 'DBM::Deep', $fn or die "Could not tie hash to $fn";
$db{key} = 'value';
print $db{key};
tied(%db)->put('key' => 'value');
print tied(%db)->get('key');
# Multi-level hash
$db->{'key1'}->{'subkey1'}="more stuff";
$db->{'wine'}->{'red'}->{'taste'}="good";
$db->{'invoice'}->{'16738'}->{'customernum'}=455;
# get keys or values
@k=keys(%$db);
@k=values(%$db);
@k=keys( %{$dbm->{'A'}} ); # Gets subkeys for 'A'
【讨论】：