如何从 Perl 中的哈希数组创建哈希哈希？答案

【问题标题】：How can I create a hash of hashes from an array of hashes in Perl?如何从 Perl 中的哈希数组创建哈希哈希？
【发布时间】：2011-04-20 11:21:55
【问题描述】：

我有一个哈希数组，都具有相同的一组键，例如：

my $aoa= [
 {NAME=>'Dave', AGE=>12, SEX=>'M', ID=>123456, NATIONALITY=>'Swedish'},
 {NAME=>'Susan', AGE=>36, SEX=>'F', ID=>543210, NATIONALITY=>'Swedish'},
 {NAME=>'Bart', AGE=>120, SEX=>'M', ID=>987654, NATIONALITY=>'British'},
]

我想编写一个子例程，使用给定的键层次结构将其转换为哈希哈希：

my $key_hierarchy_a = ['SEX', 'NATIONALITY'];
aoh_to_hoh ($aoa, $key_hierarchy_a) = @_;
 ...
}

将返回

{M=>
  {Swedish=>{{NAME=>'Dave', AGE=>12, ID=>123456}},
   British=>{{NAME=>'Bart', AGE=>120, ID=>987654}}}, 
 F=>
  {Swedish=>{{NAME=>'Susan', AGE=>36,  ID=>543210}}
}

请注意，这不仅会创建正确的密钥层次结构，还会删除现在冗余的密钥。

我陷入了需要在其正确的分层位置创建新的、最内部的哈希的点上。

问题是我不知道“深度”（即键的数量）。如果我有一个常数，我可以这样做：

%h{$inner_hash{$PRIMARY_KEY}}{$inner_hash{$SECONDARY_KEY}}{...} = filter_copy($inner_hash,[$PRIMARY_KEY,$SECONDARY_KEY])

所以也许我可以编写一个循环，一次添加一个级别，从哈希中删除该键，而不是将剩余的哈希添加到“当前”位置，但这有点麻烦而且我也不确定如何在哈希哈希中保留“位置”...

【问题讨论】：

您预期的数据结构看起来不对。例如，如果有两个瑞典女性，$expected{FEMALE}{Swedish} 应该包含什么？您展示它的方式（一直向下散列），这个问题没有一个好的答案。我的假设是 $expected{FEMALE}{Swedish} 需要是一个 array reference 包含修剪的哈希引用。
这其实并不那难做到，但你必须列出一个更明确的结构。也许在 XML 中描述层次结构，哪些是属性/一次出现的元素，哪些可以被多次列出。
关于 FM 所说的，您不需要 arrayref，但您需要某种独特的密钥系统。数组很好，因为它们天生就创建了唯一索引。

标签： perl hash perl-data-structures

【解决方案1】：

use Data::Dumper;

my $aoa= [
 {NAME=>'Dave', AGE=>12, SEX=>'M', ID=>123456, NATIONALITY=>'Swedish'},
 {NAME=>'Susan', AGE=>36, SEX=>'F', ID=>543210, NATIONALITY=>'Swedish'},
 {NAME=>'Bart', AGE=>120, SEX=>'M', ID=>987654, NATIONALITY=>'British'},
];

sub aoh_to_hoh {
  my ($aoa, $key_hierarchy_a) = @_;
  my $result = {};
  my $last_key = $key_hierarchy_a->[-1];
  foreach my $orig_element (@$aoa) {
    my $cur = $result;
    # song and dance to clone an element
    my %element = %$orig_element;
    foreach my $key (@$key_hierarchy_a) {
      my $value = delete $element{$key};
      if ($key eq $last_key) {
        $cur->{$value} ||= [];
        push @{$cur->{$value}}, \%element;
      } else {
        $cur->{$value} ||= {};
        $cur = $cur->{$value};
      }
    }
  }
  return $result;
}

my $key_hierarchy_a = ['SEX', 'NATIONALITY'];
print Dumper(aoh_to_hoh($aoa, $key_hierarchy_a));

根据@FM 的评论，您确实需要一个额外的数组级别。

输出：

$VAR1 = {
          'F' => {
                   'Swedish' => [
                                  {
                                    'ID' => 543210,
                                    'NAME' => 'Susan',
                                    'AGE' => 36
                                  }
                                ]
                 },
          'M' => {
                   'British' => [
                                  {
                                    'ID' => 987654,
                                    'NAME' => 'Bart',
                                    'AGE' => 120
                                  }
                                ],
                   'Swedish' => [
                                  {
                                    'ID' => 123456,
                                    'NAME' => 'Dave',
                                    'AGE' => 12
                                  }
                                ]
                 }
        };

编辑：哦，顺便说一句 - 如果有人知道如何优雅地克隆参考内容，请教。谢谢！

编辑编辑：@FM 有帮助。现在好多了：D

【讨论】：

Storable::dclone 可用于一般复制深层数据结构的内容。

【解决方案2】：

正如您所经历的，编写代码来创建任意深度的哈希结构有点棘手。访问此类结构的代码同样棘手。这不禁让人疑惑：你真的想这样做吗？

一种更简单的方法可能是将原始信息放入数据库中。只要您关心的键被编入索引，数据库引擎将能够非常快速地检索感兴趣的行：给我所有 SEX = 女性和 NATIONALITY = 瑞典人的人。现在听起来很有希望！

您可能还会发现这个loosely related question 感兴趣。

【讨论】：

也许你是对的。有时间我应该看看 Perl 中的数据库。