terraform：local_file 依赖与 null_resource 导致：没有这样的文件或目录答案

【问题标题】：terraform: local_file dependency with null_resource resulting in: no such file or directoryterraform：local_file 依赖与 null_resource 导致：没有这样的文件或目录
【发布时间】：2021-10-05 05:32:23
【问题描述】：

我有一个null_resource 执行一个 docker 命令，该命令创建一个 lambda zip 文件（这是唯一的方法，因为我需要一些通常通过 apt-get 或 yum install 获得的编译库） - 因此不使用其他terraform 提供了用于创建 lambda 文件的模块：

resource "null_resource" "install_dependencies" {
  provisioner "local-exec" {
    command = "docker run -w ${path.cwd}/lambda_folder/ foot.bar.docker >> ${path.cwd}/lambda_folder/lambda.zip"
  }
}

为了上传带有aws_lambda_function资源的lambda文件，我需要使用local_file数据源：

data "local_file" "lambda_file" {
  filename = "${path.module}/lambda_folder/lambda.zip"
  depends_on = [
    null_resource.install_dependencies
  ]
}

上传 lambda 资源：

resource "aws_lambda_function" "database_rotation" {
  vpc_config {
    subnet_ids         = data.aws_subnet_ids.subnet_ids.ids
    security_group_ids = [data.aws_security_group.rotation_sg.id]
  }
  filename         = data.local_file.lambda_file.content
  function_name    = "foo_bar_lambda"
  role             = aws_iam_role.iam_for_lambda.arn
  handler          = "lambda_function.lambda_handler"
  runtime          = "python3.8"
  timeout          = 120
  environment { variables = var.env_vars }

  depends_on = [null_resource.install_dependencies]
}

这一切在第一次运行时运行良好 - 在我有 null_resource 和 data.local_file.lambda_file 的任何状态之前 - 但是一旦我的初始部署成功，terraform 将失败并出现以下错误：

Error: open ./lambda_folder/lambda.zip: no such file or directory

  on main.tf line 62, in data "local_file" "lambda_file":
  62: data "local_file" "lambda_file" {

这是有道理的 - null_resource 没有运行，也没有创建 lambda.zip 文件。我的问题是，如何解决这个问题？如何确保data.local_file.lambda_file 不是每次都被触发，或者null_resource 每次我运行 terraform 时都被执行，从而创建/上传相同的 lambda.zip 文件我有点迷茫，我会很感激任何帮助。谢谢！

【问题讨论】：

你可以使用这个：terraform.io/docs/language/meta-arguments/…。但我不确定这是否会有所帮助。

标签： aws-lambda terraform

【解决方案1】：

不幸的是，这很难。您可以将triggers 输入用于null_resource，结合fileexists 函数和uuid 函数，如下所示：

resource "null_resource" "install_dependencies" {
  triggers = {
    filefound = fileexists("${path.cwd}/lambda_folder/lambda.zip") ? "1" : uuid()
  }
  provisioner "local-exec" {
    command = "docker run -w ${path.cwd}/lambda_folder/ foot.bar.docker >> ${path.cwd}/lambda_folder/lambda.zip"
  }
}

这保证了它会在文件丢失时重新运行，但问题是它每次都会运行两次（当它发现文件丢失时，一次，当触发时再次运行创建文件后从 UUID 更改为“1”。但是，后续运行不应重新创建资源。

编辑： 没有办法做到这一点真的让我很困扰，所以I built a module 解决了这个问题。在您的情况下，您可以像这样使用它：

module "conditional_trigger" {
  source = "Invicton-Labs/conditional-trigger/null"
  // A new output ID will only be generated when this field is `true`
  regenerate = fileexists("${path.cwd}/lambda_folder/lambda.zip")
}

resource "null_resource" "install_dependencies" {
  triggers = {
    id = module.conditional_trigger.uuid
  }
  provisioner "local-exec" {
    command = "docker run -w ${path.cwd}/lambda_folder/ foot.bar.docker >> ${path.cwd}/lambda_folder/lambda.zip"
  }
}

这是一些严重的黑魔法，但它适用于大多数情况。

【讨论】：