GNUPlot - 如何控制刻度标签中的行间距？

Question

我正在尝试绘制一个在其 xticks 上有两行标签的图表。我不能再减少字体，因为它变得不可读（该图是 2x2 多图的一部分）。 问题是标签中的两行之间的距离太大，以至于它们变得太靠近下一列的标签。

我想减小行间距，使标签的行之间变得更近，但离其他标签的行更远。

我考虑过手动放置标签（使用函数来计算每行的位置），但在这样做之前，我想知道是否有人有更简单的解决方案。

非常感谢！

我在 Ubuntu 14 上使用“gnuplot 4.6 patchlevel 4”。以下是 MWE：

# Requires gnuplot >= 4.6
set terminal pdf color solid font "Helvetica, 10" enhanced size 4, 3.72
set output 'mwe.pdf'
set border 3 lc rgb "#000000"
set bmargin 9
set ylabel offset -1
TicksFont = ", 10"
Title2Font = ", 14"

set yrange[0:180 < * ]
set format y "%.0f%%"

set xtics out scale 0, 0 nomirror rotate by 90 right offset 0,0 font TicksFont
set ytics out nomirror font TicksFont
unset key

set datafile separator ";"
set style fill transparent solid 1.0 border -1
set style data boxes
set boxwidth 1.0

#Bottom-left plot
set title "C) Third (sub)plot" font Title2Font

plot '-' using ($0):2:(0xFF8080):xtic(1) notitle lc rgb variable
# Label; Value
01. Aaaaa:\nAaaaaaaaa(AA);                  100
02. Bbbbb:\nBbbbbbbbbbbb(BB);               20
03. Ccccc: Ccccccc(Ccc),\nCccccccc(CCC);    30
04. Dddd: DDDD,\nDDDDDDDDDDDD(DD);          40
;NaN
01. Aaaaa:\nAaaaaaaaa(AA);                  100
02. Bbbbb:\nBbbbbbbbbbbb(BB);               20
03. A single-liner;                         30
04. Dddd: DDDD,\nDDDDDDDDDDDD(DD);          40
;NaN
01. Aaaaa:\nAaaaaaaaa(AA);                  100
02. Bbbbb:\nBbbbbbbbbbbb(BB);               20
03. A single-liner;                         30
04. Dddd: DDDD,\nDDDDDDDDDDDD(DD);          40
05. Eeee: EEEE,\nEEEEEEEEEEEE(EE);          50
end;

Answer 1

在 gnuplot 中，您不能直接控制用于标签的行高。但是对于您的问题，有一个非常肮脏的解决方法：

您可以在换行符处拆分标签，使用增强的标签语法更改每行的字体大小，但为换行符设置不同的字体大小。所以一个标签

set label at 0,0 "first line\nsecond line" font ",10"

改为

set label at 0,0 "{/=10 first line}\n{/=10 second line} font ",8"

您的脚本更改为：

# Requires gnuplot >= 4.6
set terminal pdf color solid font "Helvetica, 10" enhanced size 4, 3.72
set output 'mwe.pdf'
set border 3 lc rgb "#000000"
set bmargin 9
set ylabel offset -1
TickSize = 10
TicksFont = ", ".TickSize
Title2Font = ", 14"

set yrange[0:180 < * ]
set format y "%.0f%%"

set xtics out scale 0, 0 nomirror rotate by 90 right offset -0.1,0 font ",8"
set ytics out nomirror font TicksFont
unset key

set datafile separator ";"
set style fill transparent solid 1.0 border -1
set style data boxes
set boxwidth 1.0

#Bottom-left plot
set title "C) Third (sub)plot" font Title2Font

set_label_size(s) = sprintf('{/=%d %s}', TickSize, s)
label(s) = strstrt(s, "\n") ? set_label_size(s[:strstrt(s, "\n")-1])."\n".set_label_size(s[strstrt(s, "\n")+1:]) : set_label_size(s)

plot '-' using ($0):2:(0xFF8080):xtic(label(strcol(1))) notitle lc rgb variable
# Label; Value
01. Aaaaa:\nAaaaaaaaa(AA);                  100
02. Bbbbb:\nBbbbbbbbbbbb(BB);               20
03. Ccccc: Ccccccc(Ccc),\nCccccccc(CCC);    30
04. Dddd: DDDD,\nDDDDDDDDDDDD(DD);          40
;NaN
01. Aaaaa:\nAaaaaaaaa(AA);                  100
02. Bbbbb:\nBbbbbbbbbbbb(BB);               20
03. A single-liner;                         30
04. Dddd: DDDD,\nDDDDDDDDDDDD(DD);          40
;NaN
01. Aaaaa:\nAaaaaaaaa(AA);                  100
02. Bbbbb:\nBbbbbbbbbbbb(BB);               20
03. A single-liner;                         30
04. Dddd: DDDD,\nDDDDDDDDDDDD(DD);          40
05. Eeee: EEEE,\nEEEEEEEEEEEE(EE);          50
end;

之前（左）和之后（右）：

Answer 2

您可以切换到epslatex 终端并直接在您的gnuplot 脚本上使用latex 语法。然后您可以使用带有负参数的\vspace{} 命令来减小行间距，如下所示：

\shortstack{01. Aaaaa: \vspace{-0.2em} \\ Aaaaaaaaa(AA)}

虽然您需要转义反斜杠：

\\shortstack{01. Aaaaa: \\vspace{-0.2em} \\\\ Aaaaaaaaa(AA)}

Answer 3

是否可以仅更改整个绘图的大小，例如将绘图宽度从 4 英寸更改为 6 英寸，将高度从 3.72 更改为 5.58？

这样，如果您将纵横比包含在不同的文档中，就会保留纵横比。

之前：

之后：