我使用 CAPSLock 键启动了一个小脚本进行导航（这只是代码的一部分）：
SetCapsLockState, AlwaysOff
CapsLock & i::
if getkeystate("alt") = 0
Send,{Up}
else
Send,+{Up}
return
CapsLock & l::
if getkeystate("alt") = 0
Send,{Right}
else
send, +{Right}
return
它在任何地方都能完美运行.. 除了在 MS Excel 中！ 当我选择一系列单元格时，选择框就在那里，但公式中没有单元格引用。 例如：求和 C3:C10 变成 =sum() 公式中实际上没有选择任何单元格。 如果我不断尝试上下多次.. 它显示，但从来没有一致。
知道如何解决这个问题吗？
提前谢谢你
【问题讨论】：
标签： excel autohotkey
问题在于您的 shift 键在按键之间被释放。
例如，尝试在 Excel 中按这样的键，您会发现您实际上并没有选择单元格，您只是突出显示它们：
Shift Down, Up Arrow, Shift Up
Shift Down, Up Arrow, Shift Up
Shift Down, Up Arrow, Shift Up
...
因此，您必须在整个选择过程中一直按住 shift 键。
这是我能想到的：
CapsLock::Shift
#If, GetKeyState("CapsLock", "P")
*i::
if (GetKeyState("Alt", "P"))
SendInput, {Blind}{Alt Up}{Up}
else
SendInput, {Up}
return
*l::
if (GetKeyState("Alt", "P"))
SendInput, {Blind}{Alt Up}{Right}
else
SendInput, {Down}
return
#If
或者像这样用三元组写得更干净：
CapsLock::Shift
#If, GetKeyState("CapsLock", "P")
*i::SendInput, % GetKeyState("Alt", "P") ? "{Blind}{Alt Up}{Up}" : "{Up}"
*l::SendInput, % GetKeyState("Alt", "P") ? "{Blind}{Alt Up}{Right}" : "{Right}"
#If
那么发生了什么？
首先我们使用简单的重映射语法(docs) 将CapsLock 重映射为Shift。
然后我们使用#If(docs)为 I 和 L 创建上下文相关热键。
只有当 CapsLock 的 物理 状态为关闭时，才会触发热键。
我们需要物理状态，因为逻辑状态（默认）被重新映射为 shift。
热键是使用 * 修饰符创建的.
我切换了Send 命令SendInput，因为它是推荐的更快、更可靠的发送模式(docs)。
然后是关于{Blind}。通常，当您使用发送命令发送某些内容时，它会自动释放您可能持有的任何修饰符。但是如果你使用盲发模式(docs)，就不会出现这种情况。所以 Shift 仍然一直按住。
【讨论】：