推后是否影响标量值...（Raku）

Question

我很难理解被推送的Scalar 容器所持有的值何时以及为何在推送后受到影响。我将尝试在两个程式化的示例中说明我在更复杂的上下文中遇到的问题。

*示例 1 * 在第一个示例中，标量 $i 被推送到数组 @b 作为 List 的一部分。推送之后，标量保存的值在 for 循环的后续迭代中使用 $i++ 指令显式更新。这些更新会影响数组@b 中的值：在for 循环结束时，@b[0;0] 等于3，不再等于2。

my @b;
my $i=0;
for 1..3 -> $x {
  $i++;
  say 'Loose var $i: ', $i.VAR.WHICH, " ", $i.VAR.WHERE;
  if $x == 2 {
     @b.push(($i,1));
     say 'Pushed $i   : ', @b[0;0].VAR.WHICH, " ", @b[0;0].VAR.WHERE;
  }
}
say "Post for-loop";
say "Array       : ", @b;
say 'Pushed $i   : ', @b[0;0].VAR.WHICH, " ", @b[0;0].VAR.WHERE;

输出示例1：

Loose var $i: Scalar|94884317665520 139900170768608
Loose var $i: Scalar|94884317665520 139900170768648
Pushed $i   : Scalar|94884317665520 139900170768648
Loose var $i: Scalar|94884317665520 139900170768688
Post for-loop
Array       : [(3 1)]
Pushed $i   : Scalar|94884317665520 139900170768688

* 示例 2 * 在第二个示例中，标量 $i 是循环变量。即使$i 在被推送后更新（现在是隐式而不是显式），数组@c 中$i 的值不 推送后更改；即在for循环之后，它仍然是2，而不是3。

my @c;
for 1..3 -> $i {
  say 'Loose var $i: ', $i.VAR.WHICH, " ", $i.VAR.WHERE;
  if $i == 2 {
     @c.push(($i,1));
     say 'Pushed $i   : ', @c[0;0].VAR.WHICH, " ", @c[0;0].VAR.WHERE;
  }
}
say "Post for-loop";
say "Array       : ", @c;
say 'Pushed $i   : ', @c[0;0].VAR.WHICH, " ", @c[0;0].VAR.WHERE;;

输出示例2：

Loose var $i: Scalar|94289037186864 139683885277408
Loose var $i: Scalar|94289037186864 139683885277448
Pushed $i   : Scalar|94289037186864 139683885277448
Loose var $i: Scalar|94289037186864 139683885277488
Post for-loop
Array       : [(2 1)]
Pushed $i   : Scalar|94289037186864 139683885277448

问题：为什么示例1中@b中的$i在推送后更新，而示例2中@c中的$i没有？

编辑： 在@timotimo 的评论之后，我在示例中包含了.WHERE 的输出。这表明$i 的（WHICH/逻辑）标量标识保持不变，而其内存地址通过各种循环迭代发生变化。但它没有解释为什么在示例 2 中推送的标量仍然绑定到相同的 WHICH 身份以及旧地址（“448）”。

Answer 1

标量值只是一个容器。您可以将它们视为一种智能指针，而不是原始值。

如果你做作业

$foo = "something"; #or
$bar++;

您正在更改标量值，容器保持不变。

考虑

my @b; 
my $i=0; 
for 1..5 -> $x { 
  $i++; 
  @b.push(($i<>,1)); # decontainerize $i and use the bare value
} 
say @b;

和

my @b; 
my $i=0; 
for 1..5 -> $x { 
  $i := $i + 1;  # replaces the container with value / change value
  @b.push(($i,1)); 
} 
say @b;

两者都按预期工作。但是：在这两种情况下，列表中的事物不再是可变的，因为没有容器。

@b[4;0] = 99; 

因此会死。所以只需使用循环变量，对吗？

没有。

for 1..5 -> $x { 
  @b.push(($x,1)); # 
} 
@b[4;0] = 99; #dies

即使我们遍历一个可变事物列表。

my $one = 1;
my $two = 2;
my $three = 3;
my $four = 4;
my $five = 5;

for ($one, $two, $three, $four, $five) -> $x { 
  @b.push(($x,1)); 
} 
@b[4;0] = 99; #dies

所以这里没有发生别名，而是循环变量始终是同一个容器，并获取来自其他容器的分配值。

我们可以这样做。

for ($one, $two, $three, $four, $five) <-> $x { 
  @b.push(($x,1)); 
} 
@b[4;0] = 99; # works

for ($one, $two, $three, $four, $five) -> $x is rw { 
  @b.push(($x,1)); 
} 
@b[4;0] = 99; # works too

使“事物”可变的一种方法是使用中间变量。

for 1..5 -> $x { 
  my $j = $x;
  @b.push(($j,1)); # a new container 
} 
@b[4;0] = 99;

工作正常。或者在原始上下文中更短更多

my @b; 
my $i=0; 
for 1..5 -> $x { 
  $i++; 
  @b.push((my $ = $i, 1)); # a new anonymous container
} 
@b[4;0] = 99;
say @b; # [(1 1) (2 1) (3 1) (4 1) (99 1)]

另见：

https://perl6advent.wordpress.com/2017/12/02/#theoneandonly https://docs.perl6.org/language/containers

Answer 2

在玩了一段时间并思考了我的上述问题之后，我会打赌答案......这纯粹是我的猜测，所以如果是的话，请随意说这是无意义的，如果你发生了要知道，为什么...

在第一个示例中，$i 是在 for 循环的词法范围之外定义的。因此，$i 独立于循环及其迭代而存在。从循环内部引用$i 时，只有一个$i 会受到影响。正是这个$i 被推入@b，然后在循环中修改其内容。

在第二个示例中，$i 定义在 for 循环的词法范围内。正如@timotimo 指出的那样，每次迭代都会调用指向块的get，就像子例程一样；因此，$i 是为每次迭代新声明的，并作用于相应的块。当在循环内引用$i 时，该引用指向特定于块迭代的$i，当相应的循环迭代结束时，它通常会不复存在。但是因为在某些时候$i 被推送到@c，对特定于块迭代的$i 持有值2 的引用不能在迭代终止后被垃圾收集器删除。它将继续存在...，但在以后的迭代中仍然与 $i 不同。