确定是否设置了 Raku 中的变量

Question

我有意避免使用 defined 一词，因为变量很可能具有已定义的值，但 .defined 方法将返回 false（例如，失败）。

有什么方法可以判断一个变量是否已经设置了值？

my $foo;
say $foo; # (Any), its type object, no value assigned
my Str $bar;
say $bar; # (Str), its type object, no value assigned
my $abc = Str;
say $abc; # (Str), the type object we assigned to $abc

我们如何区分$bar（未设置值，键入为Str）与$abc（值设置为Str）？

鉴于$bar.WHICH == $abc.WHICH，但$bar.VAR.WHICH !== $abc.VAR.WHICH，以及.defined 之类的方法都将返回false，是否有任何快速简便的方法来确定是否存在设定值？

我想它可以根据默认值进行检查，但是没有办法区分值是通过未设置还是在代码中设置。

Answer 1

变量总是被设置为某种值。

如果您不将其设置为某个值，则会为您选择一个值。
具体来说，它将被设置为默认值。
（如果你不选择默认值，它将被设置为类型对象。）

my $abc;

say $abc.VAR.default.raku;
# Any

my Int $def = 42;

say $def.VAR.default.raku;
# Int

my $ghi is default(42) = 2;

say $ghi.VAR.default.raku;
# 42

---

你所要求的并不是 Raku 真正支持的东西。

不过，您可能会伪造一些接近的东西。
（Mu.new 的每个实例都是唯一的。）

sub is-not-set ( Mu $_ is raw ) {
  $_.self =:= $_.VAR.default
}

my $abc is default(Mu.new);
my $def is default(Mu.new) = Any;
my $ghi is default(Mu.new) = Mu.new;

say is-not-set $abc; # True
say is-not-set $def; # False
say is-not-set $ghi; # False

问题是分配Nil 也会将其设置为默认值。

$def = Nil;
say is-not-set $def; # True

将查找默认值并分配它。

$ghi = $ghi.VAR.default;
say is-not-set $ghi; # True

---

我认为你不应该担心这些事情。

如果您真的需要在第一次分配给变量时发生某些事情，您可以执行以下操作：

my $abc := Proxy.new(
  # this FETCH only needs to return the default
  # as this Proxy gets replaced upon the first assignment
  FETCH => -> $ { Any },

  STORE => -> $, $value {
    # replace the Proxy with a new Scalar
    $abc := do { my $abc = $value };

    say 'first assignment just happened'
  },
);

say $abc;
# Any

$abc = 1;
# first assignment just happened

say $abc;
# 1

$abc = 2;

say $abc;
# 2

do 块就在那里，所以$abc.VAR.name 返回$abc。
否则你可以写$abc := my $ = $value。

Answer 2

我认为这两个值是相同的，但容器有不同的type constraints。

试试

my Str $foo;
my  $bar = Str;

use Test;

cmp-ok $bar, &[===], $foo, 'The values are identical';
isa-ok $bar, Str;
isa-ok $foo, Str;
isa-ok $bar.VAR.of, Mu;
nok $bar.VAR.of.isa(Str), 'The container $bar is not of Str' ;
isa-ok $foo.VAR.of, Str;

done-testing();

ok 1 - The values are identical
ok 2 - The object is-a 'Str'
ok 3 - The object is-a 'Str'
ok 4 - The object is-a 'Mu'
ok 5 - The container $bar is not of Str
ok 6 - The object is-a 'Str'
1..6

Answer 3

这是一般问题还是实施问题？如果是后者，也许（ab）使用角色是一种选择？

role isUnset {}; 
my Str $a = Str but isUnset; 
say $a ~~ isUnset; 

# meanwile
$a = 'set'; 
# ...
$a = Str;

# and then
say $a ~~ isUnset; # Now False

Answer 4

my Str $bar 和 my $bar = Str 的结果相同，都是 Str 类型，但没有确定的值。 Str 是一个类型对象，而不是一个值。

如果您给$bar 一个确定的值，例如"Str"，.defined 将返回True（注意裸词周围的引号）。

Answer 5

您可以尝试为变量分配默认值，而不是保持未定义：

 my Str $bar is default("");

$bar 将是 Str 仅当它被分配了该值类型；如果通过分配 Nil 删除了它的值，它将再次默认为空字符串。事实上，变量的默认值是它的类型对象，所以：

my Str $foo;
my $bar = Str;
say $foo eqv $bar

实际上会返回 True。