从 MS Access 导出为格式化的 PDF

Question

我对 MS Access 非常陌生。目标是从 MS Access DB 导出多个 PDF 文件。目前我可以通过以下代码导出多个 Excel 文件。但我想将其导出为 PDF，表格中的格式更改很少（颜色、字体等），并在 PDF 中添加页眉和页脚注释。

Private Sub Command4_Click()
Dim rsGroup As DAO.Recordset
Dim ColumnName As String
Dim myPath As String

myPath = "E:\TestExport\"

Set rsGroup = CurrentDb.OpenRecordset("SELECT DISTINCT TableName.Column FROM TableName", dbOpenDynaset)

Do While Not rsGroup.EOF
    ColumnName = rsGroup!Column

    Dim rsExportSQL As String
    rsExportSQL = "SELECT * FROM TableName WHERE TableName.Column='" & ColumnName & "'"

    Dim rsExport As DAO.QueryDef
    Set rsExport = CurrentDb.CreateQueryDef("myExportQueryDef", rsExportSQL)


    DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, "myExportQueryDef", myPath & RegionName & ".xls", True

    CurrentDb.QueryDefs.Delete rsExport.Name

    rsGroup.MoveNext
Loop

End Sub

谢谢

Answer 1

如前所述，PDF 是结构化的、固定格式的文档文件，而不是动态数据文件。考虑以下例程：

1. 使用完整表（不是任何查询）预先设计报表作为 记录源。以任何方式（即横向/纵向、标题、字体、颜色）设置样式以供最终传播或展示。
2. 使用DoCmd.OpenReport 方法，在打印预览中打开报表，使用该方法的WhereCondition 参数有条件地按循环值更改报表的过滤器。
3. 然后运行DoCmd.OutputTo 以在同一循环中将预览报告输出为PDF 格式。注意：从不输出完整表，只输出过滤记录。

VBA代码

Private Sub Command4_Click()
  Dim rsGroup As DAO.Recordset
  Dim ColumnName As String, myPath As String

  myPath = "E:\TestExport\"

  Set rsGroup = CurrentDb.OpenRecordset("SELECT DISTINCT Column FROM TableName", _
                                        dbOpenDynaset)        
  Do While Not rsGroup.EOF
     ColumnName = rsGroup!Column

     ' OPEN REPORT, FILTERING RECORDSOURCE BY COLUMN VALUE
     DoCmd.OpenReport "ReportName", acViewPreview, , "Column='" & ColumnName & "'"
     ' OUTPUT REPORT TO FILE
     DoCmd.OutputTo acOutputReport, "ReportName", acFormatPDF, _
                                    myPath & ColumnName & ".pdf", False
     ' CLOSE PREVIEW
     DoCmd.Close acReport, "ReportName"

     rsGroup.MoveNext
  Loop

  rsGroup.Close
  Set rsGroup = Nothing
End Sub

Answer 2

Lybren 的解决方案是正确的方法。根据您要导出的所有查询创建报告，然后在 VBA 中使用Docmd.OutputTo 方法将报告导出为 PDF。下面是一个代码示例：

DoCmd.OutputTo acOutputReport, "MyReportToExport", acFormatPDF, "C:/Users/MyUserAccount/Documents/MyExportedPDF.pdf"

您也可以通过将“acOutputReport”更改为“acOutputQuery”来导出查询，但通过使用报告，您可以更好地控制格式。