如何将方法修饰符应用于 AUTOLOAD 生成的方法？

Question

我有一个非常有趣的困境。我正在开发 CVS 存储库的 Perl 脚本接口，并创建了 Perl 对象来表示 Modules、Paths 和 Files。由于Modules、Paths 和Files 都可以对它们发出CVS 命令，因此我设置了AUTOLOAD 例程以采用任何未识别的方法并在对象上发出它们，就好像它们是CVS 命令一样。

所有这些 CVS 命令的执行方式完全相同，但其中一些需要对输出进行特殊处理才能获得我想要的结果。

---

例如，我想在返回之前获取 diff 命令的输出并重新格式化它。

我用的是Moose，所以一般这种特殊处理可以如下进行：

after 'diff' => sub {
    # Reformat output here
}

问题是...我从未明确创建过diff 方法，因为它是由AUTOLOAD 生成的，而Perl 不允许我为它创建方法修饰符，因为它在技术上不存在！

有没有办法让它按我想要的方式工作？

Answer 1

将after 应用于您的AUTOLOAD 方法。

after 'AUTOLOAD' => sub {
    my $method = $The::Package::AUTOLOAD;
    $method =~ s/.*:://;
    if ($method eq 'diff') {
        # do  after diff  stuff
    } elsif ($method eq 'foo') {
        # do  after foo  stuff
    } else {
        # never mind, don't want to do anything after this function
    }
};

---

编辑：

我发现我可能想要更多地控制diff 命令，因此我在您的答案中添加了更多细节。希望有人会发现这些信息有用。

要获得更多控制权，您可以使用around！

around 'AUTOLOAD' => sub {
    my $orig = shift;
    my $self = shift;
    (my $command = $AUTOLOAD) =~ s{.+::}{};

    # Special processing
    if ($command eq 'diff') {

        #
        # Add "before" special processing here
        #

        my $output = $self->$orig(@_);

        #
        # Add "after" special processing here
        #

    }
    else {
        return $self->$orig(@_);
    }
};

这允许您在调用函数之前和之后进行特殊处理。

欲了解更多信息，请参阅：Moose::Manual::MethodModifiers

Answer 2

根据AUTOLOAD-using 类的实现程度，您可能会发现它也尊重can 方法，只需调用can 就足以创建该方法。

__PACKAGE__->can( "diff" );
after diff => sub { ... };

Answer 3

我建议您重新构建系统以使用特征，而不是依赖 AUTOLOAD 行为。如果您的行为没有分散在各处，可维护性和意图会更加明显。

例如，您可以通过以下方式执行您想要的操作：

package Trait::CVSActions;

use Moose::Role;

sub commit { print 'in commit for ' . shift . "\n" }

sub diff { print 'diffing for ' . shift . "\n" }

package Module;

use Moose;

with 'Trait::CVSActions';

package Path;

use Moose;

with 'Trait::CVSActions';

after commit => sub { print "after commit on Path\n" };

package main;

my $module = new Module;
my $path = new Path;

$module->commit;
$path->commit;

如果您希望使用 AUTOLOAD 来调度未知命令，那么这很危险，因为您可能需要对某些您不知道的特殊处理进行处理，因此您可能会导致自己未来的问题。