对具有相同键的所有元组求和（实现 Haskell Data.Map.fromListWith）[重复]

Question

我想对具有相同键的元组的值求和。

例如，

foo = [(True, 0), (True, 1), (False, 2), (True, -1), (False,4)] :: [(Bool, Int)]
putStrLn . show $ sumTuples foo

应该显示 [(False,6),(True,0)].

当然，这很容易通过Data.Map.fromListWith 实现：

sumTuples :: (Ord a, Num b) => [(a, b)] -> [(a, b)]
sumTuples = Map.toList . Map.fromListWith (+)

但我想在没有Data.Map 的帮助下实现它。

使用过滤器，我可以这样解决：

sumByFilter :: [(Bool, Int)] -> [(Bool, Int)]
sumByFilter xs =
  let trues = filter((==True) . fst) xs
      falses = filter((==False) . fst) xs
      summing = sum . map snd
  in [(True, summing trues), (False, summing falses)]

或折叠：

sumByUglyFold :: [(Bool, Int)] -> [(Bool, Int)]
sumByUglyFold =
  let initial = [(True, 0), (False, 0)]
  in foldl foldingFxn initial

foldingFxn :: [(Bool,Int)] -> (Bool, Int) -> [(Bool, Int)]
foldingFxn [(_, truAcc), (_, falseAcc)] (bool, val)
  | bool      = [(True, truAcc + val), (False, falseAcc)]
  | otherwise = [(True, truAcc), (False, falseAcc + val)]

但是，在这两种情况下，我都将第一个参数硬编码为布尔值。但是，我希望能够对任何未预定义的键执行此操作——当然，如果我有字符串键，我无法对所有键进行模式匹配。

如何使我的代码通用？

Answer 1

你必须按键排序，然后按它分组，然后对每个组求和：

sumThem = map sumGroup . groupBy fstEq . sortOn fst
  where
    sumGroup (x:xs) = (fst x, sum $ map snd (x:xs))
    sumGroup _ = error "This can never happen - groupBy cannot return empty groups"

    fstEq (a, _) (b, _) = a == b

请注意，此处排序是必不可少的操作，因为groupBy 仅对consequitive 元素进行分组。