如何获取无类型常量数据的地址？

Question

在一个常见的 Delphi 模式中，我将一个值作为 untyped const 传递给一个函数：

procedure DoSomething(const Something; SomethingLength: Integer);
begin
   //...
end;

在这个例子中，我恰好传递了 Windows FORMATETC 结构：

procedure Test;
var
   omgp: TFormatEtc;
begin
   omgp := Default(TFormatEtc);
   omgp.cfFormat := RegisterClipboardFormat('CF_PNG');
   omgp.ptd := nil;
   omgp.dwAspect := DVASPECT_CONTENT or DVASPECT_THUMBNAIL;
   omgp.lindex := -1; //all pages
   omgp.tymed := TYMED_HGLOBAL;

   DoSomething(omgp, SizeOf(omgp));
end;

我需要得到这个数据的地址，所以我可以把它传递给一个底层的Windows函数需要指向数据的指针的东西。

为了做到这一点，我一直使用Pointer(@data)：

procedure DoSomething(const Something; SomethingLength: Integer);
begin
   SomethingThatNeedsAPointer(Pointer(@Something));
end;

直到这个 API 调用在一种特殊情况下失败（它返回错误的值）。 没有特别的原因，我碰巧仔细查看了正在传递的指针值。当我在调试器中检查every参数值时，我注意到了一些可怕的事情。我注意到：

@Something
Pointer(@Something)

返回不同的值。

• @Something应该已经是一个指针了
• Pointer(@Something) 应该是多余的演员表

哪种方式正确获取无类型数据的地址？

编辑：人们去吃午饭的东西与问题无关。我已经编辑了这个问题，希望人们能专注于这个问题，而不是例子。

Answer 1

我无法在 XE8 中重现您的情况。 调试器显示@Salt 和Pointer(@Salt) 的地址相同。

同样，这个测试 sn-p 的输出是相同的。 我只能假设调试器告诉你的东西在某种程度上是不真实的。

（更新：XE7 中的测试重现了调试器中的错误。不过 sn-p 的结果是相同的。）

program Test;

{$APPTYPE CONSOLE}

procedure Test1(p: Pointer);
begin
  WriteLn(Cardinal(p));
end;

procedure Test(const Salt);
begin
  Test1(@Salt);
  Test1(Pointer(@Salt));
  Test1(Addr(Salt));
end;

var
  s:AnsiString;
begin
  s := 'Test';
  Test( s[1]);
  ReadLn;
end.

Answer 2

这是一个调试器错误，调试器错误地报告了Pointer(@Salt) 的值。我可以在 XE5、XE6 和 XE7 中重现故障，但不能在 XE4 和 XE8 中重现。所以看起来这是一个在 XE5 中引入并在 XE8 中删除的缺陷。

每当您看到这样的问题时，调试器故障总是可能的。在这种情况下，我们可以用这个程序证明故障出在调试器上：

{$APPTYPE CONSOLE}

uses
  System.SysUtils;

procedure DoSomething(const Salt; SaltLength: Integer);
begin
  Writeln(IntToHex(NativeUInt(Pointer(@Salt)), 8));
  Writeln(IntToHex(NativeUInt(@Salt), 8));
end;

procedure Test;
var
  salt: AnsiString;
begin
  salt := 'salt';
  DoSomething(salt[1], Length(salt));
end;

begin
  Test;
end.

这个程序输出：

007C9BD4 007C9BD4

即使 @Salt 和 Pointer(@Salt) 被调试器赋予不同的值。

注意这个程序

{$APPTYPE CONSOLE}

procedure DoSomething(const Salt; SaltLength: Integer);
var
  i: Integer;
  P: PAnsiChar;
begin
  P := @Salt;
  for i := 0 to SaltLength-1 do
  begin
    Writeln(P^);
    inc(P);
  end;
end;

procedure Test;
var
  salt: AnsiString;
begin
  salt := 'salt';
  DoSomething(salt[1], Length(salt));
end;

begin
  Test;
end.

输出：

s 一种 l 吨