将 TInterfacedObject 强制转换为接口

Question

According to the Delphi docs，我可以使用as 运算符将TInterfacedObject 转换为接口。

但这对我不起作用。强制转换给出编译错误：“运算符不适用于此操作数类型”。

我使用的是 Delphi 2007。

这是一些代码（控制台应用程序）。包含错误的行被标记。

program Project6;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  IMyInterface = interface
    procedure Foo;
  end;

  TMyInterfacedObject = class(TInterfacedObject, IMyInterface)
  public
    procedure Foo;
  end;

procedure TMyInterfacedObject.Foo;
begin
  ;
end;

var
  o: TInterfacedObject;
  i: IMyInterface;
begin
  try
    o := TMyInterfacedObject.Create;
    i := o as IMyInterface;  // <--- [DCC Error] Project6.dpr(30): E2015 Operator not applicable to this operand type
  except
    on E:Exception do
      Writeln(E.Classname, ': ', E.Message);
  end;
end.

Answer 1

快速解答

您的界面需要有一个 GUID，as 运算符才能工作。转到IMyInterface = interface 之后的第一行，在任何方法定义之前，然后按 Ctrl+G 以生成新的 GUID。

更长的评论

接口的as 运算符需要一个GUID，因为它调用IUnknown.QueryInterface，而这又需要一个GUID。如果您在将 INTERFACE 转换为其他类型的 INTERFACE 时遇到此问题，那也没关系。

首先，您不应该将TInterfacedObject 强制转换为接口，因为这意味着您同时持有对实现对象的引用 (TInterfacedObject) 和对已实现接口的引用 (@ 987654327@)。这是有问题的，因为您混合了两个生命周期管理概念：TObject 一直到有人调用 .Free 为止；您有理由确定在您不知情的情况下，没有任何东西会在您的对象上调用.Free。但是接口是引用计数的：当您将接口分配给变量时，引用计数器会增加，当该实例超出范围（或分配其他内容）时，引用计数器会减少。当引用计数器达到零时，对象将被释放 (.Free)！

这里有一些看起来很无辜的代码，很快就会遇到很多麻烦：

procedure DoSomething(If: IMyInterface);
begin
end;

procedure Test;
var O: TMyObjectImplementingTheInterface;
begin
  O := TMyObjectImplementingTheInterface.Create;
  DoSomething(O); // Works, becuase TMyObject[...] is implementing the given interface
  O.Free; // Will likely AV because O has been disposed of when returning from `DoSomething`!
end;

修复非常简单：将O 的类型从TMyObject[...] 更改为IMyInterface，如下所示：

procedure DoSomething(If: IMyInterface);
begin
end;

procedure Test;
var O: IMyInterface;
begin
  O := TMyObjectImplementingTheInterface.Create;
  DoSomething(O); // Works, becuase TMyObject[...] is implementing the given interface
end; // `O` gets freed here, no need to do it manually, because `O` runs out of scope, decreases the ref count and hits zero.

Answer 2

如果要使用 As 或 Supports 运算符，则需要在接口中添加 Guid，例如：

type   
  IMyInterface = interface
    ['{00000115-0000-0000-C000-000000000049}']
    procedure Foo;   
  end; 

见docwiki

Answer 3

如果您将对象 o 定义为正确的类型，则转换将是自动的。否则，您可以随时使用supports() 和/或自己致电QueryInterface。

var
  o: TMyInterfacedObject;
  i: IMyInterface;
begin
  try
    o := TMyInterfacedObject.Create;
    i := o;
  except
    on E:Exception do
      Writeln(E.Classname, ': ', E.Message);
  end;
end.