将对象转换为没有 TInterfacedObject 作为基类的接口类型

Question

我需要一个没有引用计数的类实现接口。我做了以下事情：

  IMyInterface = interface(IInterface)
      ['{B84904DF-9E8A-46E0-98E4-498BF03C2819}'] 
      procedure InterfaceMethod;
  end;

  TMyClass = class(TObject, IMyInterface)
  protected
      function _AddRef: Integer;stdcall;
      function _Release: Integer;stdcall;
      function QueryInterface(const IID: TGUID; out Obj): HResult;stdcall;
  public
      procedure InterfaceMethod;
  end;

  procedure TMyClass.InterfaceMethod;
  begin
      ShowMessage('The Method');
  end;

  function TMyClass.QueryInterface(const IID: TGUID; out Obj): HResult;
  begin
      if GetInterface(IID, Obj) then
          Result := 0
      else
          Result := E_NOINTERFACE;
  end;

  function TMyClass._AddRef: Integer;
  begin
      Result := -1;
  end;

  function TMyClass._Release: Integer;
  begin
      Result := -1;
  end;

缺少引用计数可以正常工作。但我担心的是我不能使用as 运算符将TMyClass 转换为IMyInterface：

var
  MyI: IMyInterface; 
begin
  MyI := TMyClass.Create as IMyInterface;

给我

[DCC 错误] E2015 运算符不适用于此操作数类型

当TMyClass 派生自TInterfacedObject 时，问题就消失了——也就是说，我可以在没有编译器错误的情况下进行这种转换。显然我不想使用 TInterfacedObject 作为基类，因为它会使我的类引用计数。为什么不允许这种强制转换以及如何解决它？

Answer 1

您不能在代码中使用as 的原因是您的类没有在其支持的接口列表中明确列出IInterface。即使您的接口派生自 IInterface，除非您实际列出该接口，否则您的类不支持它。

因此，简单的解决方法是像这样声明您的类：

TMyClass = class(TObject, IInterface, IMyInterface)

您的类需要实现IInterface 的原因是编译器依赖它来实现as 转换。

我想说的另一点是，一般来说，您应该避免使用接口继承。总的来说，它没有什么用处。使用接口的好处之一是您可以摆脱实现继承带来的单一继承约束。

但无论如何，所有 Delphi 接口 automatically inherit from IInterface 所以在你的情况下没有必要指定。我会这样声明你的界面：

IMyInterface = interface
  ['{B84904DF-9E8A-46E0-98E4-498BF03C2819}'] 
  procedure InterfaceMethod;
end;

更广泛地说，您应该尽量不要在接口中使用继承。通过采用这种方法，您将鼓励减少耦合并带来更大的灵活性。