方案中的迭代映射

Question

我正在观看 SICP 视频讲座，我来到了一个部分，导师正在展示使用列表的程序，所以，这里是其中之一：

(define (map p l)
   (if (null? l) 
       (list)
       (cons (p (car l))
                    (map p (cdr l)))))

我想问的是：有没有办法以迭代的方式定义map，或者cons需要执行惰性求值对吗？

Answer 1

您的原始代码几乎是尾递归的.. 唯一使它不是的是cons 部分。如果 Scheme 对 TRMC optimization 的要求与 TCO 的要求相同，则您可以保留您的代码原样，并且实现会使它对您来说是尾递归的。

由于这不是我们需要进行自己的 TRMC 优化的要求。通常在循环中迭代列表并使用累加器进行尾递归时，您会以相反的顺序获得结果，因此您可以进行反向线性更新：

(define (map proc lst)
  (let loop ((lst lst) (acc '()))
    (cond ((null? lst) (reverse! acc) acc)
          (else (loop (cdr lst) 
                      (cons (proc (car lst)) acc))))))

或者您可以一次完成所有操作：

(define (map proc lst)
  (define head (list 1))
  (let loop ((tail head) (lst lst))
    (cond ((null? lst) (cdr head))
          (else (set-cdr! tail (list (proc (car lst))))
                (loop (cdr tail) (cdr lst))))))

现在在这两种情况下，您只改变过程本身创建的结构，因此对于用户来说，它可能会以与您的示例相同的方式实现。

当你在你的实现中使用像map 这样的高阶过程时，它可能已经被这样实现了。通过将提供的map 的性能与具有很长列表的不同实现进行比较，很容易发现。执行之间的差异将告诉您它是否是 TRMCO 或提供的 map 可能已如何实现。

Answer 2

你需要接受递归才能总体上欣赏SICP和Scheme，所以试着习惯它，你以后会欣赏的，承诺。

但是，你可以：

(define (iterative-map f lst)
  (define res null)
  (do ((i (- (length lst) 1) (- i 1))) ((= i -1))
    (set! res (cons (f (list-ref lst i)) res)))
  res)

(iterative-map (lambda (x) (+ x 1)) '(1 3 5))
=> '(2 4 6)

但是如果可以避免的话，使用set! 被认为是不好的风格。

在 Racket 中，您有一组更优雅的循环：

(define (for-map f lst)
  (for/list ((i lst))
    (f i)))

(for-map add1 '(1 3 5))
=> '(2 4 6)