关于在 Groovy 中省略 'return' 关键字以返回闭包块的不一致

Question

我刚刚开始学习 Groovy。我进入了这个：https://groovy-lang.org/style-guide.html#_return_keyword_optional 因此，可以在方法定义的末尾省略“return”。好的。 尽管我更喜欢亲自使用它，但我还是想看看。 我测试了一些简单的案例来弄清楚它是如何工作的：

例如demo.groovy：

def a1 = { return { return 'hi'} }()
println a1

def a2 = { return {'hi'} }()
println a2

def a3 = { {'hi'} }()
println a3

def a4 = { {-> 'hi'} }()
println a4

我运行了脚本，结果是：

demo$_run_closure1$_closure5@21c64522
demo$_run_closure2$_closure6@460f76a6
hi
demo$_run_closure4$_closure7@1922e6d

从 a1 案例开始，我一次省略了关键字“return”。它们是 a2 和 a3 的情况。 让我摸不着头脑的是a3的情况。我希望像 a1 和 a2 的情况一样返回关闭。但它返回“hi”，而不是闭包本身。 所以我添加了另一个测试用例 a4，然后它按预期工作。

我试图搜索一些关于它的文档，但找不到合适的文档。 为什么它返回 'hi' 而不是闭包对象？

提前致谢。

仅供参考，我的 groovy 版本是：

Groovy 版本：3.0.7 JVM：15.0.1 供应商：Oracle Corporation 操作系统：Mac OS X

Answer 1

您在a3 示例中看到的不是嵌套闭包，而是嵌套代码块。

嵌套代码块

在 Java 中一个不常用的结构是匿名代码块。通常不鼓励这样做，因为这通常表明将相关代码重构为方法是有序的。但有时限制范围很有用，现在在 Groovy 中可用：

{
    def a = 1
    a++
    assert 2 == a
}
try {
    a++ // not defined at this point
} catch(MissingPropertyException ex) {
    println ex.message
}
{
    {
        // inner nesting is another scope
        def a = 'banana'
        assert a.size() == 6
    }
    def a = 1
    assert a == 1
}

请注意，在 Groovy 中，在任何方法调用之后具有代码块外观结构将被视为尝试将闭包作为方法调用中的最后一个参数传递。即使在换行之后也会发生这种情况。因此，在任何其他块（例如 if-then-else 语句或另一个匿名代码块）之后启动匿名代码块是安全的。在其他任何地方，您可能需要用分号终止前面的语句。在这种情况下，请参阅上面关于重构代码的注释！ :-)

---

^{来源：https://groovy-lang.org/releasenotes/groovy-3.0.html#_nested_code_blocks}

您可以在groovyConsole 中运行此脚本并转到“脚本”->“检查 AST”以查看编译器在这种情况下生成的内容：

你可以看到a3是一个隐式返回'hi'的闭包。

在 Groovy 3 中添加了对嵌套代码块的支持。如果您在 Groovy 2 中运行相同的示例，您会看到以下编译错误：

org.codehaus.groovy.control.MultipleCompilationErrorsException: startup failed:
/home/wololock/workspace/groovy-3-sandbox/src/main.groovy: 7: Ambiguous expression could be either a parameterless closure expression or an isolated open code block;
   solution: Add an explicit closure parameter list, e.g. {it -> ...}, or force it to be treated as an open block by giving it a label, e.g. L:{...} @ line 7, column 12.
   def a3 = { {'hi'} }()
              ^

1 error