Emacs/AUCTeX 前缀参数

Question

在 LaTeX 模式下，C-c C-c 绑定到：

(TeX-command-master &optional OVERRIDE-CONFIRM)

通常这个交互函数会运行一个命令，也许是一个 LaTeX 编译，要求确认。

在tex-buf.el 中写着：

如果给出前缀参数 OVERRIDE-CONFIRM，确认将 取决于它是肯定的，而不是 `TeX-command-list' 中的条目。

这对我来说有点神秘，阅读 C-h v TeX-command-list 并没有帮助。

如何将前缀参数传递给“TeX-command-master”，以避免所有确认请求？

Answer 1

我认为这个问题的要点是“如何在没有所有按键和确认的情况下从 AUCTeX 快速编译我的 TeX 文档？”

我对此的回答是使用 latexmk 命令，而不是试图强迫 AUCTeX 这样做。

latexmk -pdf -pvc myfile.tex

latexmk 将监控有问题的文件，并在您保存后立即重建它。如果您使用好的 pdf 查看器，它会注意到 PDF 的变化并立即重新显示。在 OS X 上，skim 可以很好地解决这个问题。

Answer 2

我对 OVERRIDE-CONFIRM 位有一段时间感到困惑，但无法弄清楚它应该如何工作。如果你想在你的文件上自动运行 Latex，而不用担心先保存它，或者确认你想要 Latex（而不是查看、bibtex 等），你可以使用这样的函数：

(defun my-run-latex ()
  (interactive)
  (TeX-save-document (TeX-master-file))
  (TeX-command "LaTeX" 'TeX-master-file -1))

将此绑定到方便的东西，当您想使用默认处理命令时，您仍然可以使用C-c C-c。如果“Latex”不是您要调用的处理器，您可能需要修改 TeX-command 行。

Answer 3

如果您只是想在没有确认对话框的情况下编译乳胶源，只需将以下内容添加到您的 .emacs 中：

(setq TeX-command-force "")

然后您可以使用 C-c C-c 编译源代码，它不会要求确认。此解决方案的唯一问题是您不能再更改命令，但对于大多数文档，您将不想这样做。我可能会建议您同时将其添加到您的 .emacs 以获得更大的灵活性，为您提供与前一种行为等效的 C-c C-c：

(define-key LaTeX-mode-map "\C-c\C-a"   
   ;;; 'a' for ask, change to anything you want 
  (lambda (arg) (interactive "P") 
    (let ((TeX-command-force nil)) 
      (TeX-command-master arg)))) 

然后您可以直接处理您的文档，执行 C-x C-s、C-c C-c 然后 C-c C-v 来查看它。就像其他人建议的那样，您也可以对 save 命令执行相同的操作，并让它在保存时自动编译，但我的一些文档在 CVS 中，所以我避免在上面添加钩子。

感谢 Ivan 在这方面提供了一些帮助 - 不知道他是否在 StackOverflow 上

Answer 4

构建和查看

同样，此解决方案不是修改TeX-command-master 的行为，而是重写它。该命令的重写版本名为build-view，遵循相当简单的逻辑。

1. 如果 LaTeX 文件缓冲区未修改，则运行默认查看器；
2. 如果缓冲区脏了，它会运行默认的 LaTeX 编译器，并在构建之后在默认查看器中打开输出。

代码如下：

(defun build-view ()
  (interactive)
  (if (buffer-modified-p)
      (progn  
    (let ((TeX-save-query nil)) 
    (TeX-save-document (TeX-master-file)))
    (setq build-proc (TeX-command "LaTeX" 'TeX-master-file -1))
    (set-process-sentinel  build-proc  'build-sentinel))
    (TeX-view)))

(defun build-sentinel (process event)    
  (if (string= event "finished\n") 
      (TeX-view)
    (message "Errors! Check with C-`")))

您现在可以键入 M-x build-view 并启动指定的构建视图过程或将其与新的键绑定相关联，例如“F2”：

(add-hook 'LaTeX-mode-hook '(lambda () (local-set-key (kbd "<f2>") 'build-view)))

注意：正如 Tyler 所建议的，TeX-save-query 变量在本地进行了更改，因此旧的 C-c C-c/TeX-command-master 不受影响，并且会继续询问确认。

请编辑此代码以使其更好或更易于阅读！

Answer 5

OVERRIDE-CONFIRM 的谜团似乎还在继续。同时有小伙伴建议，如果我们无法管理TeX-command-master，我们可以简单地重写它。

在我的版本中，根据他的，如果不修改缓冲区，则启动外部查看器；如果缓冲区被修改，则运行编译器。 没有确认保存或运行给定命令的所有内容。

(defun my-run-latex ()
  (interactive)
  (if (buffer-modified-p)
      (progn  
        (setq TeX-save-query nil) 
        (TeX-save-document (TeX-master-file))
        (TeX-command "LaTeX" 'TeX-master-file -1))
    (TeX-view)))

当然可以将my-run-latex 绑定到任何键绑定。

从用户的角度来看，这是我自己问题的解决方案。 我是否单击关闭标签？好吧，从好奇的人的角度来看，我仍然有兴趣了解神秘的 TeX-command-master 技术细节。

如果有人碰巧知道……

附： 是的，TeX-save-query 覆盖了保存文件请求，同样使用TeX-command-master，即C-c C-c。但仍会要求您确认命令操作。

Answer 6

查看Emacs' documentation 以了解前缀参数。通常，您可以向命令传递带有 C-u 的前缀参数，后跟一个数字。对于一位数字，您也可以只键入 Meta 后跟数字。因此，要将正前缀参数传递给TeX-command-master，您可以输入：

M-1 C-c C-c

然而，这实际上会添加另一个 minibuffer 确认，即关于用于编译 LaTeX 源的 shell 命令。如果没有前缀参数，则使用依赖于命令的默认值。

如果你想避免使用命令的问题，你可以通过以下方式将未记录的变量TeX-command-force绑定到“LaTeX”：

(setq TeX-command-force "LaTeX")

但是，这将有一个缺点，即您基本上将 Cc Cc 绑定到“latex”命令，您不能使用任何其他命令，例如“bibtex”或“view”。

除此之外，LaTeX 模式不允许对 C-c C-c 进行任何自定义。您最好的选择是 advise 函数 TeX-command-query 或将 C-c C-c 绑定到包装函数以动态设置 TeX-command-force。如果您还想自动保存缓冲区，后者可能是首选选项。