格式化列表：使用不在列表中的参数

Question

这是我写的代码sn-p，但不起作用：

(let ((separator "|")
      (text '("Just" "do" "it" "!")))
  (format t "~{~A~A~%~}" text separator))

输出应如下所示：

Just|
do|
it|
!|

但是，它不会那样工作 - 当我在 ~{~} 中时，我不知道如何从列表之外添加元素。我可以这样做：

(format t "~{~A|~%~}" text)

但这不允许我从变量中使用separator，这就是我所追求的。

现在我知道我可以通过在每个偶数位置添加分隔符来将text 与分隔符合并，但这对我来说看起来很难看。 format还有其他方法吗？

Answer 1

稍微改变一下 renzo 的答案：如果我们使用 SPECIAL 声明，我们就不需要全局变量：

(defun %d1 (stream arg &rest args)
  (declare (ignore args)
           (special delim))
  (princ arg stream)
  (princ delim stream))

(defun my-print (list delim)
  (declare (special delim))
  (format nil "~{~/%d1/~%~}" list))

Answer 2

您可以使用Tilde Slash 格式指令，它允许用户定义的函数作为格式说明符。这只是给你一个可能的例子，可能有很多变化：

CL-USER> (defvar *separator* " ")
*SEPARATOR*
CL-USER> (defun q(stream arg &rest args)
           (declare (ignore args))
           (format stream "~a~a" arg *separator*))
Q
CL-USER> (let ((*separator* "|")
               (text '("Just" "do" "it" "!")))
           (format t "~{~/q/~%~}" text))
Just|
do|
it|
!|
NIL
CL-USER> (let ((*separator* "+++")
               (text '("Just" "do" "it" "!")))
           (format t "~{~/q/~%~}" text))
Just+++
do+++
it+++
!+++
NIL
CL-USER> 

Answer 3

这是一个黑客：

CL-USER 49 > (let ((separator "|")
                   (text '("Just" "do" "it" "!")))
                (format t
                        (concatenate 'string "~{~A" separator "~%~}")
                        text))
Just|
do|
it|
!|

在分隔符字符串中转义波浪号：

CL-USER 56 > (flet ((fix-tilde (string)
                      (with-output-to-string (s)
                        (loop for c across string
                              when (char= c #\~)
                              do (write-string "~~" s)
                              else do (write-char c s)))))
               (let ((separator (fix-tilde "~a~a"))
                     (text '("Just" "do" "it" "!")))
                 (format t
                         (concatenate 'string "~{~A" separator "~%~}")
                         text)))
Just~a~a
do~a~a
it~a~a
!~a~a