Windows 7 与 Windows 10 - 处理批处理文件中带有空格的文件夹名称

Question

我正在尝试创建一个必须在Windows 7 和Windows 10 上运行的批处理脚本。但是，每个处理带有空格的文件夹名称的方式似乎有所不同，我必须以不同的方式转义它们。

特别是在Windows 7 上，我成功使用了以下命令：

start cmd.exe /k "%OpenOCD_bin_Path%\openocd.exe -f %OpenOCD_bin_Path%\..\scripts\interface\ftdi\SuperDongle.cfg -f %OpenOCD_bin_Path%\..\scripts\target\nrf52.cfg"

OpenOCD_bin_Path 包含一个文件夹，其中包含空格；它引用的完整路径是：

C:\Users\Rafael\AppData\Roaming\GNU MCU Eclipse\OpenOCD\0.10.0-7-20180123-1217\bin

但是，在Windows 10 上，同一行失败并显示以下错误：

'C:\Users\Rafael\AppData\Roaming\GNU' 不是内部或外部命令、可运行程序或批处理文件。

如果我将命令更改为：

start cmd.exe /k ""%OpenOCD_bin_Path%"\openocd.exe -f "%OpenOCD_bin_Path%"\..\scripts\interface\ftdi\SuperDongle.cfg -f "%OpenOCD_bin_Path%"\..\scripts\target\nrf52.cfg"

成功了。

相反，如果我在 Windows 7 上运行该命令，我会收到以下错误：

'""C:\Users\Rafael\AppData\Roaming\GNU' 不是内部或外部命令、可运行程序或批处理文件。

注意这个版本前面额外的""。

TLDR;有没有一种方法可以在两个系统上都进行这项工作，而无需使用开关来检测正在运行的操作系统？

Answer 1

cmd.exe 很傻，它会从命令中删除开始和结束的引号，但是有一个技巧可以打败它：

start cmd.exe /k if 1==1 "%OpenOCD_bin_Path%\openocd.exe" -f "%OpenOCD_bin_Path%\..\scripts\interface\ftdi\SuperDongle.cfg" -f "%OpenOCD_bin_Path%\..\scripts\target\nrf52.cfg"

无论如何，从start 调用 cmd.exe 毫无意义，只需使用start：

start "" "%OpenOCD_bin_Path%\openocd.exe" -f "%OpenOCD_bin_Path%\..\scripts\interface\ftdi\SuperDongle.cfg" -f "%OpenOCD_bin_Path%\..\scripts\target\nrf52.cfg"

重要的是%OpenOCD_bin_Path% 在所有系统上的引号都相同。您通常不会引用环境中设置的路径，因为在需要时很难再次删除引号。

你可以去掉引号，但理想情况下你应该避免处理批处理文件中的字符串操作，因为转义问题。

这是一个尝试处理这两种情况的示例：

@echo off
goto run_tests

:stripquotes
FOR /F "tokens=1,*" %%A IN ('echo.%*') DO set %%~A=%%~B
goto :EOF

:test
call :stripquotes mynewvar %*
echo DEBUG: mynewvar is now %mynewvar%
start "" "%mynewvar%\app.exe" "par am 1" param2 "par am 3"
goto :EOF


:run_tests
set OpenOCD_bin_Path=c:\foo bar\baz
call :test %OpenOCD_bin_Path%

set OpenOCD_bin_Path="c:\foo bar\baz"
call :test %OpenOCD_bin_Path%

Answer 2

使用我在评论中提供的任何一个想法都应该绕过空格。

使用CD /D：

@Echo Off
Set "OpenOCD_bin_Path=%AppData%\GNU MCU Eclipse\OpenOCD\0.10.0-7-20180123-1217\bin"
CD /D "%OpenOCD_bin_Path%\..\scripts" 2>Nul || Exit / B
Start "" Cmd /K "..\bin\openocd.exe -f interface\ftdi\SuperDongle.cfg -f target\nrf52.cfg"

或者你也可以在不明确启动cmd.exe的情况下尝试：

@Echo Off
Set "OpenOCD_bin_Path=%AppData%\GNU MCU Eclipse\OpenOCD\0.10.0-7-20180123-1217\bin"
CD /D "%OpenOCD_bin_Path%\..\scripts" 2>Nul || Exit / B
Start ..\bin\openocd.exe -f interface\ftdi\SuperDongle.cfg -f target\nrf52.cfg

使用Start /D：

@Echo Off
Set "OpenOCD_bin_Path=%AppData%\GNU MCU Eclipse\OpenOCD\0.10.0-7-20180123-1217\bin"
Start "" /D "%OpenOCD_bin_Path%" Cmd /K "openocd.exe -f ..\scripts\interface\ftdi\SuperDongle.cfg -f ..\scripts\target\nrf52.cfg"

或者在没有明确启动cmd.exe的情况下再次：

@Echo Off
Set "OpenOCD_bin_Path=%AppData%\GNU MCU Eclipse\OpenOCD\0.10.0-7-20180123-1217\bin"
Start "" /D "%OpenOCD_bin_Path%" openocd.exe -f ..\scripts\interface\ftdi\SuperDongle.cfg -f ..\scripts\target\nrf52.cfg