使用 Gremlin 在二分图上随机游走

Question

我想在 groovy 中使用 gremlin 在有向二部图上随机游走，根据给定的用户偏好（用户喜欢的项目）对项目进行排名。

该图具有以下基本结构：

[User1] ---'likes'---> [ItemA] [ItemB]

以下是我想出的查询：

def runRankQuery(def userVertex) {
    def m = [:]
    def c = 0
    while (c < 1000) {
        userVertex
            .out('likes')   // get all liked items of current or similar user
            .shuffle[0]     // select randomly one liked item
            .groupCount(m)  // update counts for selected item
            .in('likes')    // get all users who also liked item
            .shuffle[0]     // select randomly one user that liked item
            .loop(5){Math.random() < 0.5}   // follow liked edge of new user (feed new user in loop) 
                                            // OR abort query (restart from original user, outer loop)      
            .iterate()
        c++
    }
    m = m.sort {a, b -> b.value <=> a.value}
    println "intermediate result $m"
    m.keySet().removeAll(userVertex.out('likes').toList())
    // EDIT (makes no sense - remove): m.each{k,v -> m[k] = v / m.values().sum()}
    // EDIT (makes no sense - remove): m.sort {-it.value }
    return m.keySet() as List;
}

但是，此代码没有找到新项目（上面示例中的 [ItemB]），而是仅找到给定用户喜欢的项目（例如 [ItemA]）。

• 我需要改变什么来提供一个新用户（例如 [User2]），让循环步骤返回到“out('likes')”步骤以便继续步行？

• 此代码运行后，是否可以将其视为“个性化 PageRank”的实现？

---

这里是运行示例的代码：

g = new TinkerGraph()

user1 = g.addVertex()
user1.name ='User1'
user2 = g.addVertex()
user2.name ='User2'
itemA = g.addVertex()
itemA.name ='ItemA'
itemB = g.addVertex()
itemB.name ='ItemB'

g.addEdge(user1, itemA, 'likes')
g.addEdge(user2, itemA, 'likes')
g.addEdge(user2, itemB, 'likes')

println runRankQuery(user1)

还有输出：

intermediate result [v[2]:1000]
[]
==>null
gremlin> g.v(2).name
==>ItemA
gremlin> 

Answer 1

我发现这是一个非常奇怪的问题。我发现了几个很难解释的非常奇怪的问题，最后，我不确定它们为什么会这样。对我来说很奇怪的两件大事是：

1. 我不确定shuffle 步骤是否有问题。在您的情况下，它似乎没有正确随机化。我似乎无法在此案例之外重现问题，因此我不确定它是否与您的数据大小或其他原因有关。
2. 我在使用Math.random() 跳出循环时遇到了奇怪的问题。

无论如何，我想我已经在这里抓住了你代码的精髓，我所做的更改似乎可以满足你的需求：

runRankQuery = { userVertex ->
    def m = [:]
    def c = 0
    def rand = new java.util.Random()
    while (c < 1000) {
        def max = rand.nextInt(10) + 1
        userVertex._().as('x')
            .out('likes')   
            .gather.transform{it[rand.nextInt(it.size())]}
            .groupCount(m) 
            .in('likes')    
            .gather.transform{it[rand.nextInt(it.size())]}
            .loop('x'){it.loops < max}  
            .iterate()
        c++
    }
    println "intermediate result $m"
    m.keySet().removeAll(userVertex.out('likes').toList())
    m.each{k,v -> m[k] = v / m.values().sum()}
    m.sort {-it.value }
    return m.keySet() as List;
}

我通过从收集的列表中随机选择一个顶点，将shuffle 替换为我自己品牌的“shuffle”。我还随机选择了一个max 循环而不是依赖Math.random()。当我现在运行它时，我想我得到了你正在寻找的结果：

gremlin> runRankQuery(user1)                                       
intermediate result [v[2]:1787, v[3]:326]
==>v[3]
gremlin> runRankQuery(user1)
intermediate result [v[2]:1848, v[3]:330]
==>v[3]
gremlin> runRankQuery(user1)
intermediate result [v[2]:1899, v[3]:339]
==>v[3]
gremlin> runRankQuery(user1)
intermediate result [v[2]:1852, v[3]:360]
==>v[3]

您可能还可以让Math.random() 工作，因为它在我使用它的一些迭代中表现得可以预见。