如何将所选数据从 50 个 Excel 工作簿传输到单个工作簿？答案

【问题标题】：How to transfer selected data from 50 Excel workbooks to a single workbook?如何将所选数据从 50 个 Excel 工作簿传输到单个工作簿？
【发布时间】：2021-11-05 17:27:32
【问题描述】：

文件夹循环有效，但单元格循环无效。我有一个包含 50 个 Excel 文件和一个目标 Excel 文件的文件夹。数据应该从文件夹转到目标 Excel 文件：

#include <file.au3>
#include <Excel.au3>
opt("WinTitleMatchMode", 2)
$path = "C:\Users\User\Desktop\Nezavisimai\Papka2\"
$FileListShort = _FileListToArray($path, "*.xlsx", 1, True)
$ProgExcel = _Excel_Open()
$workbookDestiny = _Excel_BookNew($ProgExcel)

$LineDestiny = 1
_Excel_RangeWrite($workbookDestiny, $workbookDestiny.Activesheet, "Sample type", "A" & $LineDestiny)
_Excel_RangeWrite($workbookDestiny, $workbookDestiny.Activesheet, "Sample name", "B" & $LineDestiny)
_Excel_RangeWrite($workbookDestiny, $workbookDestiny.Activesheet, "Result", "C" & $LineDestiny)

For $i = 1 to $FileListShort[0]

$workbookSource =  _Excel_BookOpen($ProgExcel, $FileListShort[$i], False, False)
For $LineSource = 2 to 30
$sampletype = _Excel_RangeRead($workbookSource, "Данные", "A" & $LineSource)
$samplename = _Excel_RangeRead($workbookSource, "Данные", "B" & $LineSource)
$sampleresult = _Excel_RangeRead($workbookSource, "Данные", "C" & $LineSource)
$sampleobs = _Excel_RangeRead($workbookSource, "Данные", "D" & $LineSource)
If $sampletype = "Sample"  Then
    If $sampleobs <> "Over limit" Then
        $LineDestiny = $LineDestiny + 1
        _Excel_RangeWrite($workbookDestiny, "Лист1", $sampletype, "A" & $LineDestiny)
        _Excel_RangeWrite($workbookDestiny, "Лист1", $sampletype, "B" & $LineDestiny)
        _Excel_RangeWrite($workbookDestiny, "Лист1", $sampletype, "C" & $LineDestiny)
     EndIF
EndIF
Next
_Excel_BookClose($workbookSource, False)
Next

问题可能在这里：

If $sampletype = "Sample"  Then
        If $sampleobs <> "Over limit" Then
           $LineDestiny = $LineDestiny + 1

【问题讨论】：

能否提供一些文件进行测试？ 2-3 个文件以及预期的结果应该是什么样子。
drive.google.com/drive/folders/… 感谢您的评论。
那么，您只想将所有文件放在一张纸上吗？
外来生物学家，是的。 wb1 中的 Sheet1 + wb2 中的 Sheet1 + wb3 中的 Sheet1。和 wb1 中的 Sheet2 + wb2 中的 Sheet2 + wb3 中的 Sheet2。

标签： excel autoit

【解决方案1】：

这可能是一个很好的起点。让我知道它是否对您有所帮助，或者是否缺少某些内容。

; Combine Excel files
#include <Excel.au3>
#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>

$allFiles_A = _FileListToArray(@ScriptDir & '\files\', '*.xlsx', $FLTA_FILES, True)
;~ _ArrayDisplay($allFiles_A)

; Create application object
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpen Example", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

Local $oWorkbook_result = _Excel_BookNew($oExcel)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

For $i = 1 To $allFiles_A[0]
    $end = $i * 35 + 1
    $start = $end - 35

    Local $sWorkbook_source = _Excel_BookOpen($oExcel, $allFiles_A[$i])
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF Error", "Error opening '" & $sWorkbook_source & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_RangeCopyPaste($sWorkbook_source.Activesheet, $sWorkbook_source.Activesheet.Range("A1:D35"))
    _Excel_RangeCopyPaste($oWorkbook_result.Activesheet, Default, $oWorkbook_result.Activesheet.Range('A' & $start & ':D' & $end), False, Default, Default, True)
    _Excel_BookClose($sWorkbook_source)
Next

;Autofit
$oWorkbook_result.ActiveSheet.Columns("A:E").AutoFit

【讨论】：