使用带有泛型的枚举

Question

我正在尝试创建一个通用类，我可以使用一组枚举来启动其中的值。例如：

constructor TManager<TEnum>.Create;
var
  enum: TEnum;
  enumObj: TMyObject;
begin
  fMyObjectList:=  TObjectDictionary<TEnum,TMyObject>.Create([doOwnsValues],10);
  for enum:= Low(TEnum) to High(TEnum) do
  begin
    enumObj:= TMyObject.Create();
    fMyObjectList.Add(enum, enumObj);
  end;
end;

另外，后面的方法会通过枚举值获取对象，例如：

function TManager<TEnum>.Fetch(enum: TEnum): TMyObject;
begin
  fMyObjectList.TryGetValue(enum, Result);
end;

然而，作为通用参数传递，delphi 并不知道 TEnum 将是一个枚举。我可以以某种方式强制执行吗？

Answer 1

您不能约束一个泛型参数，使得low() 和high() 可以在泛型类中使用。唯一可用的约束是类或接口约束。

据我所知，该语言没有提供通用方法来枚举通用枚举类型。可能你能做的最好的事情就是使用 RTTI，牺牲编译时类型的安全性（如 Tobias 所示）。

---

阅读了 Tobias 的回答后，您似乎真正想要的是 TObjectDictionary<TEnum,TMyObject>。那是因为您希望能够在给定 TEnum 键的情况下找到 TMyObject 实例。你想要TObjectDictionary 而不是TDictionary，因为前者接管了TMyObject 实例的所有权。完成后您需要有人将它们全部释放，您不妨让TObjectDictionary为您做。

有关所有权方面的示例，请参阅@RRUZ 在此处的回答：Example for using Generics.Collections.TObjectDictionary

Answer 2

正如 David 所说，您能做的最好的事情就是在运行时使用 RTTI。

    type  
      TRttiHelp = record
        class procedure EnumIter<TEnum {:enum}>; static;
      end;

    class procedure TRttiHelp.EnumIter<TEnum {:enum}>;
    var
      typeInf: PTypeInfo;
      typeData: PTypeData;
      iterValue: Integer;
    begin
      typeInf := PTypeInfo(TypeInfo(TEnum));
      if typeInf^.Kind <> tkEnumeration then
        raise EInvalidCast.CreateRes(@SInvalidCast);

      typeData := GetTypeData(typeInf);
      for iterValue := typeData.MinValue to typeData.MaxValue do
        WhateverYouWish;
    end;  

虽然我不知道当你的枚举定义了值时代码的行为，例如

    (a=9, b=19, c=25)

---

编辑：

如果您想将iterValue 返回到枚举，您可以使用以下函数，取自enum helper class by Jim Ferguson

class function TRttiHelp.EnumValue<TEnum {:enum}>(const aValue: Integer): TEnum;
var
  typeInf: PTypeInfo;
begin
  typeInf := PTypeInfo(TypeInfo(TEnum));
  if typeInf^.Kind <> tkEnumeration then
    raise EInvalidCast.CreateRes(@SInvalidCast);

  case GetTypeData(typeInf)^.OrdType of
    otUByte, otSByte:
      PByte(@Result)^ := aValue;
    otUWord, otSWord:
      PWord(@Result)^ := aValue;
    otULong, otSLong:
      PInteger(@Result)^ := aValue;
  else
    raise EInvalidCast.CreateRes(@SInvalidCast);
  end;
end;

然后，您可以在构造函数中使用一般提供的作为字典的索引。