MASM32 中令人困惑的括号

Question

我正在尝试掌握 MASM32，但对以下内容感到困惑：

我认为括号是用于间接的，所以如果我有一个预定义的变量

 .data
   item dd 42

然后

 mov ebx, item

会将“item”的内容，即数字 42，放入 ebx 和

 mov ebx, [item]

会将“item”的地址，即存储 42 的位置，放入 ebx。

但控制台应用程序中的以下代码：

 mov ebx, item
 invoke dwtoa, ebx, ADDR valuestr 
 invoke StdOut, ADDR valuestr
 mov ebx, [item]
 invoke dwtoa, ebx, ADDR valuestr 
 invoke StdOut, ADDR valuestr

打印 42 两次。要获取“项目”的地址，我似乎需要

 mov ebx, [OFFSET item]
 invoke dwtoa, ebx, ADDR valuestr 
 invoke StdOut, ADDR valuestr

谁能解释一下 MASM 中方括号的含义，或者给我一个好的参考。

Answer 1

MASM 对于具有类型的汇编语言来说是不寻常的。 MASM 知道是因为您如何定义符号item，它是DWORD 类型的内存位置。当您将它用作操作数时，您知道您（可能）意味着您想要存储在地址中的值，而不是地址的值。因此，无论您使用item 还是[item]，MASM 都假定您的意思是后者。如果你真的想要项目的地址，你需要使用OFFSET item。

另一方面，如果您使用item = 42 将item 定义为常量，那么mov ebx, item 将加载立即值。由于这种模糊性，您需要知道如何定义 item 以确定它是立即操作数还是内存操作数，最好避免使用裸符号作为操作数。

我应该补充一点，当您仅使用符号或数字时，方括号 [] 对 MASM 几乎没有任何意义。仅当您将它们与寄存器一起使用时，它们才有意义。下面是一些例子：

item    DD  42
const   =   43

    mov eax, item             ; memory operand (the value stored at item)
    mov eax, [item]           ; memory operand
    mov eax, OFFSET item      ; immediate operand (the address of item)
    mov eax, [OFFSET item]    ; immediate operand

    mov eax, const            ; immediate operand (43)
    mov eax, [const]          ; immediate operand
    mov eax, ds:[const]       ; memory operand (the value at address 43)
    mov eax, fs:30h           ; memory operand (the value at address 30h + fs base)
    mov eax, OFFSET const     ; immediate operand
    mov eax, [OFFSET const]   ; immediate operand

    mov eax, 42               ; immediate operand
    mov eax, ebx              ; register operand (the value of EBX)
    mov eax, [ebx]            ; indirect operand (the value pointed to by EBX)

因此，如果没有寄存器，方括号只会显示您的意图。如果您打算将符号用作内存操作数，则应在符号周围加上方括号，并将 OFFSET 与您打算用作立即值的符号一起使用。