F# - 我怎样才能将一个整数分成（大部分相等）比这更好的“桶”？

Question

我有一个整数，我想将它分成一个大小尽可能相等的整数“桶”列表。 一些例子：

• 将 10 除以 2 应该会给我一个列表，如“[ 5; 5 ]” (5+5=10)，或者，
• 将 20 除以 3 应该会给我一个列表，如“[ 7; 7; 6 ]” (7+7+6=20)，或者，
• 将 15 除以 4 应该会给我一个列表，如“[ 4; 4； 4； 3 ]” (4+4+4+3) 之类的。

较大的bucket是在末端还是中间还是混入都没有关系——它是划分一个进程并发处理，顺序无关紧要。

我写了一些代码，看起来还可以，但看起来太乱了，很难推理：

let integerBuckets total divider =
    match total, divider with
    | 0, _  -> [ 0 ]
    | 1, _ -> [ 1 ]
    | _, 0 -> [ total ] // Should  never happen, but checked just in case.
    | _, 1 -> [ total ]
    | _ ->
        let result = (double total) / (double divider)
        let remainder = total % divider
        [ for _ in 0 .. (remainder - 1) -> int (ceil result) ]
            @ [ for _ in 0 .. (divider - remainder - 1) -> int (floor result) ]

integerBuckets 15 4

我真的不喜欢 for 循环中的数学；很容易出错和/或意外更改。但我不确定的不仅仅是数学。

谁能给我一些指导，告诉我如何将它“整理”成更容易阅读的更好的 F#？

我不是要求某人提供更好的代码 sn-p，而是要求我指出我应该研究的领域，以便自己学习使代码变得更好。

Answer 1

我认为下面的方法会奏效。基本上，我生成一个商列表，然后沿着列表分配 1 个单位的余数，直到它被完全消耗掉。

let integerBuckets total divider =
    let rem = total % divider
    let quo = total / divider
    let dividerList = [1..divider]
    [ for _ in dividerList do yield quo ]  //create list of quotients
    |> List.map2 (+) [for i in dividerList do if i <= rem then 1 else 0] //distribute remainder

编辑：

上面描述的功能可以总结如下：

let integerBuckets2 total divider =
    let rem,quo = total % divider,total / divider
    [ for i in [1..divider] do yield if i <= rem then quo + 1 else quo ]

Answer 2

我建议您对问题采取更加面向数据的方法来拆分作业以进行处理。如果您将要处理的项目存储在一个数组中，那么您可以使用数组函数来操作它们。以下是一些可能的方法：

let chunkByChunkCount array chunkCount =
    let chunkSize = 
        (float (Array.length array) / float chunkCount)
        |> ceil
        |> int
    array |> Array.chunkBySize chunkSize

chunkByChunkCount [| 1 .. 15 |] 4
// [|[|1; 2; 3; 4|]; [|5; 6; 7; 8|]; [|9; 10; 11; 12|]; [|13; 14; 15|]|]



let dealIntoChunks array chunkCount =
    array
    |> Array.indexed
    |> Array.groupBy (fun (i, _) -> i % chunkCount)
    |> Array.map snd
    |> Array.map (Array.map snd)

dealIntoChunks [| 1 .. 15 |] 4
// [|[|1; 5; 9; 13|]; [|2; 6; 10; 14|]; [|3; 7; 11; 15|]; [|4; 8; 12|]|]