模式匹配 Data.Sequence 类似列表

Question

我使用Data.Sequence 代替列表以获得更好的性能。使用列表，我们可以执行以下操作

foo :: [Int] -> Int
foo [] m = m
foo (x:xs) m = ...

如何使用Data.Sequence 来实现这一点。我尝试了以下方法：

foo:: S.Seq Int -> Int
foo S.empty m = m
foo (x S.<: xs) m = ...

我认为解决方案涉及使用S.viewl 和S.viewr，但似乎无法弄清楚如何使用。

Answer 1

ViewPatterns 可能是去这里的方式。您的代码不起作用，因为您需要首先在您的Seq 上调用viewl 或viewr 以获得ViewL 或ViewR 类型的内容。 ViewPatterns 可以很好地处理这个问题：

{-# LANGUAGE ViewPatterns #-}

foo (S.viewl -> S.EmptyL)    = ... -- empty on left
foo (S.viewl -> (x S.:< xs)) = ... -- not empty on left

这相当于：

foo seq = case S.viewl seq of
    S.EmptyL    -> ...
    (x S.:< xs) -> ...

Answer 2

从 GHC 7.8 开始，您可以将 pattern synonyms 与 view patterns 一起用于此目的：

{-# LANGUAGE ViewPatterns, PatternSynonyms #-}

import qualified Data.Sequence as Seq

pattern Empty   <- (Seq.viewl -> Seq.EmptyL)
pattern x :< xs <- (Seq.viewl -> x Seq.:< xs)
pattern xs :> x <- (Seq.viewr -> xs Seq.:> x)

从 GHC 7.10 开始，您还可以将其设为双向模式同义词，以便 Empty、(:<) 和 (:>) 也可以用作“构造函数”：

{-# LANGUAGE ViewPatterns, PatternSynonyms #-}

import qualified Data.Sequence as Seq

pattern Empty   <- (Seq.viewl -> Seq.EmptyL)  where Empty = Seq.empty
pattern x :< xs <- (Seq.viewl -> x Seq.:< xs) where (:<)  = (Seq.<|) 
pattern xs :> x <- (Seq.viewr -> xs Seq.:> x) where (:>)  = (Seq.|>)