传递记录参数而不首先将其声明为变量

Question

如果我试图调用具有记录类型（不是对象）作为参数的过程，是否可以以某种方式“内联”传递该参数的详细信息而无需先声明该类型的变量？

例如假设我有这个简单的记录类型：

type TMyRecord = record
  AString: string;
  AnInt: Integer;
end;

还有这个过程声明：

procedure MyProcedure(Rec: TMyRecord);

如果我想调用 MyProcedure，我必须声明一个 TMyRecord 类型的变量还是可以执行以下操作：

MyProcedure(TMyRecord("Test", 10));

这不起作用（XE2）（得到一个关于它的编译器错误，需要一个“）”）。

那么，我可以这样做吗？或者不可能。

谢谢

Answer 1

只是玩弄约翰·伊斯利的想法：

type TRec = record
  X: string;
  Y: Integer;
end;

procedure TestRec(const Rec: array of const);
var
  R: TRec;

begin
  R.X:= string(Rec[0].VUnicodeString);
  R.Y:= Rec[1].VInteger;
  ShowMessage(R.X + IntToStr(R.Y));
end;

procedure TForm1.Button7Click(Sender: TObject);
begin
  TestRec(['Test', 22]);
end;

可以将记录字段作为array of const 参数传递，并将这些参数分配给本地记录变量。

Answer 2

可以使用advanced record 结构。

有关advanced records 的更多信息，请参阅Delphi 帮助中的Records (advanced) section。

这是一个小型原型，用于查看在您的情况下如何在函数/过程调用中预初始化记录：

Type
  TRecord = record
   AString : String;
   AnInt : Integer;
   Constructor Create( Const s : String; i : Integer);
  end;

constructor TRecord.Create(const s: String; i: Integer);
begin
  AString := s;
  AnInt := i;
end;

procedure DoSomething( theRec : TRecord);
begin
  WriteLn(theRec.AString, ' ',theRec.AnInt);
end;

begin
  DoSomeThing( TRecord.Create('S',1));
  ReadLn;
end.

查看 Delphi RTL，请参阅单元 system.types (XE2) 中记录类型 TPoint 和 TRect 的定义。 他们定义了一些重载的Create 构造函数，它们在很多地方用于在函数/过程调用中预初始化记录结构。

Answer 3

会很好！但是，没有。

如果内联传递确实是您的目标，那么也许开放数组参数会适合您。

Procedure MyProcedure(const Vars: Array of Variant);
begin
  ShowMessage(VarToStr(Vars[0])+'  '+VarToStr(Vars[1]));
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
   MyProcedure(['Test', 12]);
end;

您还可以传递一个常量数组，它基本上是一个 TVarRec 数组，它是一个变体记录，其中还包括类型信息作为 VType。这是有趣的东西..

可以在 Rudy 的 Delphi Corner 上找到一篇出色的文章： Rudy's Delphi Corner, Open Array Parameters

Answer 4

您提出的问题与代码可读性有关，并且有一种解决方案可以避免创建变量。 VCL 将此解决方案与TPoint 和TRect 记录一起使用。

考虑TPoint的定义：

type
  TPoint = record
    X,Y integer
  end;

要将TPoint 传递给您可能执行的过程：

var
  MyPoint : TPoint;

begin
  MyPoint.X := 5;
  MyPoint.Y := 7;
  DoSomething( MyPoint );
end;

这很好，但是当使用工厂函数Point 也可以使用时需要 3 行：

begin
  DoSomething( Point(5,7) );
end;

在 Delphi 中，函数声明如下：

function Point( X, Y : integer ) : TPoint;
begin
  Result.X := X;
  Result.Y := Y;
end;

然后你可以调用这个函数'inline'来快速创建记录'on the fly' 你会看到为TRect等提供了相同的功能。我经常将这样的工厂函数与记录声明放在一起如下，即使我不打算使用它们：

type
  TMyRecord = record
    A : integer;
    B : string;
  end;

function MyRecord( A : integer; const B : string ) : TMyRecord;
begin
  Result.A := A;
  Result.B := B;
end;

使用这种技术可以提高代码的可读性，还可以确保您不会意外忽略设置记录元素。