传递任意一组成对参数，其中一个成对项需要是任意数据类型

Question

我有一个函数，我想向其传递任意数量的成对参数（即String 变量和第二个任意类型（可能是String、Integer 等） - 因此我声明了这对是Object。可能有一对或多对这种性质。

因此，我能想到的最明显的结构是Tuple(Of String, Object)

这是功能：

Private Function TableLookup(
        table As DataTable,
        ByVal columnNamesAndKeys As List(Of Tuple(Of String, Object)),
        resultColumnName As String) As Object

    Dim filterExpression As String = ""
    For i = 0 To columnNamesAndKeys.Count
        Dim lookupColumn As String = columnNamesAndKeys(i).Item1
        Dim lookupKey As Object = columnNamesAndKeys(i).Item2
        Dim keyType = lookupKey.GetType()
        If keyType IsNot table.Columns(lookupColumn).DataType Then Return Nothing
        If keyType Is GetType(String) Then
            filterExpression += IIf(Len(filterExpression) > 0, " AND ", "") + $"{lookupColumn} = '{lookupKey}'"
        ElseIf keyType Is GetType(Date) Then
            filterExpression += IIf(Len(filterExpression) > 0, " AND ", "") + $"{lookupColumn} = #{lookupKey:M/dd/yyyy h:mm:ss tt}#"
        Else
            filterExpression += IIf(Len(filterExpression) > 0, " AND ", "") + $"{lookupColumn} = {lookupKey}"
        End If
    Next
    Dim row = table.Select(filterExpression).FirstOrDefault()
    Return If(row Is Nothing, Nothing, row(resultColumnName))
End Function

如此调用（对于单对）：

Dim someKey As Integer
Dim someValue = TableLookup(
    dtbSomeTable,
    New List(Of Tuple(Of String, Object))
       From {("SomeKey", DirectCast(someKey, Object)).ToTuple},
    "SomeOtherColumn")

因此（对于多对）：

Dim someKey As Integer
Dim someOtherKey As String
Dim someValue = TableLookup(
    dtbSomeTable,
    New List(Of Tuple(Of String, Object))
        From {("SomeKey", DirectCast(someKey, Object)).ToTuple,
              ("SomeOtherKey", DirectCast(someOtherKey, Object)).ToTuple},
    "SomeOtherColumn")

所以这作品- 但每次调用它感觉非常笨拙，必须创建一个 Tuples 的临时列表，然后将每个 Tuple 和 DirectCast 声明为 Object 以遵守强类型要求。

该函数的重点是在整个代码中提供一个简单的单行代码，以快速查找具有潜在多个、任意标准的列，但是调用中的所有这些操作使得任何不幸不得不维护的人都难以理解它这个...

是否有一种更智能/更简洁的方法来传递任意一组配对参数，其中一个配对项需要是任意Type？

Answer 1

您可以通过将Parameter Array (ParamArray ) 与value tuples 结合使用来实现此目的。这使您可以使用任意数量的参数轻松调用该方法，无需显式列表或数组实例化，既没有值的 New 关键字也没有任何强制转换。请注意，我们必须交换columnNamesAndKeys 和resultColumnName，因为用于传递columnNamesAndKeys 的ParamArray 必须是该方法的最后一个参数。

使用示例：

Dim result = TableLookup(
    dtbSomeTable,
    "ResultColumn",
    ("id", 12), ("name", "Joe"), ("date", #2022/10/28#), ("someKey", someValue))

适配功能：

Private Function TableLookup(
    table As DataTable,
    resultColumnName As String,
    ParamArray columnNamesAndKeys() As (key As String, value As Object)
) As Object

    Dim filterExpression As String = ""
    For i = 0 To columnNamesAndKeys.Length - 1
        Dim lookupColumn As String = columnNamesAndKeys(i).key
        Dim lookupKey As Object = columnNamesAndKeys(i).value
        Dim keyType = lookupKey.GetType()
        If keyType IsNot table.Columns(lookupColumn).DataType Then Return Nothing
        If filterExpression.Length > 0 Then
            filterExpression += " AND "
        End If
        If keyType Is GetType(String) Then
            filterExpression += $"{lookupColumn} = '{DirectCast(lookupKey, String).Replace("'", "''")}'"
        ElseIf keyType Is GetType(Date) Then
            filterExpression += $"{lookupColumn} = #{lookupKey:yyyy/MM/dd h:mm:ss tt}#"
        Else
            filterExpression += $"{lookupColumn} = {lookupKey}"
        End If
    Next
    Dim row = table.Select(filterExpression).FirstOrDefault()
    Return If(row Is Nothing, Nothing, row(resultColumnName))
End Function

我也做了一些重构。

• 由于我使用了命名元组，因此您可以按名称访问字段，而不仅仅是Item1 或“Item2”。
• 有条件地添加 " AND " 部分可以在冗长的 If Then Else ...
• 我将字符串值中的任何单引号替换为两个单引号。例如，像 "John's Pub" 这样的字符串在 SQL 表示法中变成 'John''s Pub'。
• For i = 0 To columnNamesAndKeys.Count 是错误的。索引从0 到Count - 1。既然我们现在有一个数组，我们必须使用Length。