是否可以将所有命令及其输出记录到文件中？ [命令]

Question

我正在尝试创建应用程序脚本的静默安装日志，我需要记录命令并输出到日志文件。

这就是它的样子——它是我的 .cmd 文件的一部分。 现在我需要为每一行创建变量（SET SETUP_0X=），但这个解决方案不是最好的，因为我可以编写更多命令。

SET LogPath=C:\Logs
SET LogFile=%LogPath%\App_Install.log 2>&1

call :Loguj --------------------------------------------------------------------------------
call :Loguj --------------------------------LOG-Install-START-------------------------------
call :Loguj --------------------------------------------------------------------------------
ECHO. >>%LogFile%

:Commands
SET SETUP_01=App.exe /S
SET SETUP_02=regedit /s SomeReg.reg
SET SETUP_03=DIR
SET SETUP_04=...


(...)
(goto Installation)

:Installation
call :Loguj %SETUP_01%
%SETUP_01% >> %LogFile%

call :Loguj %SETUP_02%
%SETUP_02% >> %LogFile%

call :Loguj %SETUP_03%
%SETUP_03% >> %LogFile%

call :Loguj %SETUP_04%
%SETUP_04% >> %LogFile%



:Finishing
Do other commands, but don't log this.

ECHO. >>%LogFile%
call :Loguj --------------------------------------------------------------------------------
call :Loguj --------------------------------LOG-Install-STOP--------------------------------
call :Loguj --------------------------------------------------------------------------------

因此可以改进它以不创建变量，而是记录从步骤：安装到步骤：完成到日志文件的所有命令和输出？

Answer 1

使用for /f 循环遍历变量并将整个内容放入代码块中，以一次性重定向所有输出：

:Installation
(for /f "tokens=2 delims==" %%a in ('set setup_') do (
  call :loguj %%a
  %%a
)) >> %LogFile% 2>&1

或不设置变量：

:Installation
(for  %%a in ("app.exe /s" "regedit /s somereg.reg" "dir" "...") do (
  call :loguj %%a
  %%~a
)) >> %LogFile% 2>&1
goto :eof
:loguj
echo --- %~1 ---

注意：如果有很多命令，您可能会达到cmd 行限制。

你可以把它写得更具可读性：

:Installation
(for  %%a in (
   "app.exe /s"
   "regedit /s somereg.reg"
   "dir"
   "..."
  ) do (
    call :loguj %%a
    %%~a
)) > log.txt 2>&1