在 Stata 中使用并行列表生成新变量答案

【问题标题】：generate new variable using parallel lists in Stata在 Stata 中使用并行列表生成新变量
【发布时间】：2020-09-19 09:04:59
【问题描述】：

我正在尝试从 Stata 中的两个并行列表生成一组新变量。我有一组列是劳动力中每个人口统计组的百分比，另一组列是特定职业中每个人口统计组的百分比。我想将后者除以前者来为每个组创建一个拥挤分数。

local pct_lf "pct_lf_tot_Male-pct_lf_tot_o_f_65_plus
* pct in labor force by demo group
local pct_occ "pct_Male-pct_o_f_65_plus" 
* pct in occupation by demo group
local n : word count `pct_occ'

forvalues i = 1/`n' {
     local a : word `i' of `pct_lf'
     local b : word `i' of `pct_occ' 
     gen crd_`b'=`b'/`a'
}

这段代码有一个语法错误，我还没弄清楚。我想知道是否有另一种方法可以做到这一点？通过将一个变量列表除以另一个变量列表以作为并行列表的顺序生成一个新变量？

【问题讨论】：

错误是什么？
您的代码看起来正确。如果我不得不大胆猜测，您的两个列表中可能有不同数量的元素。一般来说，我会避免在变量列表中使用“-”-通配符。这很容易出错。

标签： stata stata-macros

【解决方案1】：

代码不正确。 word # of 不会取消 varlists 的缩写。

单词的规则是单词用空格分隔，除了引号绑定。例外在这里无关紧要。因此，每个通配符 varlist 就是一个单词。

. display `: word count "pct_lf_tot_Male-pct_lf_tot_o_f_65_plus"'
1

没有您的数据，我们无法进行任何真实的测试，但可以肯定的是，您需要类似的东西

unab pct_lf : pct_lf_tot_Male-pct_lf_tot_o_f_65_plus
* pct in labor force by demo group
unab pct_occ : pct_Male-pct_o_f_65_plus 
* pct in occupation by demo group

local n : word count `pct_occ'

forvalues i = 1/`n' {
     local a : word `i' of `pct_lf'
     local b : word `i' of `pct_occ' 
     gen crd_`b'=`b'/`a'
}

【讨论】：