XSLT：如何将某些 XML 元素名称替换为其他元素名称

Question

例如这是我的 XML 文件：

<?xml version="1.0" encoding="UTF-8" ?>
<products>
 <product>
   <code>37</code>
   <ws_code>T37</ws_code>
   <barcode>11111111</barcode>
 </product>
</products>

我想改成这样：

<?xml version="1.0" encoding="UTF-8" ?>
<products>
 <product>
   <ProductCode>37</ProductCode>
   <ProductBarcode>11111111</ProductBarcode>
 </product>
</products>

我正在处理一个 XSLT 文件（缺少）：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="product/code">
        <ProductCode><xsl:apply-templates select="@*|node()" /></ProductCode>
    </xsl:template>
    <xsl:template match="product/barcode">
        <ProductBarcode><xsl:apply-templates select="@*|node()" /></ProductBarcode>
    </xsl:template>
</xsl:stylesheet>

实际上，XML 文件来自服务器，我无法对此文件进行任何更改。

如何使用 XSLT 更改这些元素名称并删除一些标签，以及如何链接 XSLT 和 XML 文件？

要更改的标签名称是：

代码 --> 产品代码
ws_code --> 应该删除
条码 --> ProductBarcode

Answer 1

您的 XSLT 非常接近您想要的，只是它没有删除 ws_code 元素并且可能更简单一些。

要删除ws_code 元素，请创建一个与之匹配的模板以不执行任何操作。

鉴于您的输入 XML，您不需要匹配 product/code 或 product/barcode。只有code 和barcode 会匹配这些元素。

您可以在模板匹配中使用<apply-templates/> 而不是<xsl:apply-templates select="@*|node()"/>。这将处理当前节点的所有子节点：参见Applying Template Rules。

通过在标识模板中使用*|@* 而不是node()|@*，它不会匹配文本节点，因此不会输出元素之间的空格。 code 和 barcode 下面的文本仍然通过文本节点的 built-in Template Rule 输出。

下面的 XSLT 实现了你想要的：

<xsl:template match="*|@*">
    <xsl:copy>
        <xsl:apply-templates select="*|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="code">
    <ProductCode>
        <xsl:apply-templates/>
    </ProductCode>
</xsl:template>

<xsl:template match="barcode">
    <ProductBarCode>
        <xsl:apply-templates/>
    </ProductBarCode>
</xsl:template>

<xsl:template match="ws_code"/>

Answer 2

将以下 XSLT-1.0 文件（我将其命名为 d.xslt）应用于您的上述输入 XML 文件（我将其命名为 d.xml(

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*" />

    <!-- identity template -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="ws_code[local-name(..) = 'product']" />

    <xsl:template match="product/code">
        <ProductCode><xsl:value-of select="text()" /></ProductCode>
    </xsl:template>

    <xsl:template match="product/barcode">
        <ProductBarcode><xsl:value-of select="text()" /></ProductBarcode>
    </xsl:template>

</xsl:stylesheet>

我在 Linux/Ubuntu 上使用以下命令/XSLTProcessor 对此进行了测试：

xsltproc d.xslt d.xml | xmlindent -f -nbe

结果是：

<?xml version="1.0"?>
<products>
    <product>
        <ProductCode>37</ProductCode>
        <ProductBarcode>11111111</ProductBarcode>
    </product>
</products>

根据需要。

此 XSLT 代码确实将具有 product 节点作为父节点的 code 和 barcode 元素分别替换为 ProductCode 和 ProductBarcode 元素。 ws_code 节点被忽略，被忽略的 空格 被 <xsl:strip-space...> 消除。