Perl 数据结构到 xml

Question

我有类似下面的 perl 数据：

$data = {
   id => 1,
   name => "A",
   users  => [ { id => 1, name => "u1" }, { id => 2, name => "u2" } ],
   groups => [ { id => 1, name => "g1" } ]
};

我想把它转换成如下的xml：

<map>
  <item id="1" name="A">
     <users>
        <user id="1" name="u1"/>
        <user id="2" name="u2"/> 
     </users>
     <groups>
        <group id="1" name="g1"/>
     </groups>         
  </item>
</map>

我可以手动显式地创建每一行。不过，我正在寻找任何 CPAN 模块基础解决方案。

我尝试了 XML::Twig，但没有去任何地方。我过去曾用过 XML::Simple 来做这样的事情，但这次想尝试其他东西，因为 XML::Simple 一直受到不好的评价。

Answer 1

您可以像 Sobrique 的方法一样执行此操作，但使用较少的硬编码字符串，如下所示：

#!/usr/bin/env perl
use strict; use warnings;

use XML::Twig;

my $data = {
    id => 1,
    name => "A",
    users  => [ { id => 1, name => "u1" }, { id => 2, name => "u2" } ],
    groups => [ { id => 1, name => "g1" } ]
};

sub array_to_elts {
    my ( $root, $name, $arrayref ) = @_;
    map { $root->insert_new_elt($name, $_) } @{ $arrayref };
}

my $twig  = XML::Twig
    ->new()
    ->set_xml_version("1.0")
    ->set_encoding('utf-8');

my $map = XML::Twig::Elt->new('map');
$twig->set_root($map);

my $item  = $map->insert_new_elt(
    'item',
    { id => $data->{'id'}, name => $data->{'name'} },
);

my $lines = $item->insert_new_elt('groups');
my $links = $item->insert_new_elt('users' );

array_to_elts($lines, 'group', $data->{'groups'});
array_to_elts($links, 'user',  $data->{'users' });

$twig->set_pretty_print('indented');
$twig->print;

您可以不遗余力地减少硬编码的 val 并更多地基于原始数据，但它很快就会变得难以阅读。..

Answer 2

使用XML::LibXML 的“通用”方式。您可能需要在“else”部分添加新代码来处理其他类型的结构。

#!/usr/bin/perl
use warnings;
use strict;

use XML::LibXML;

my $data = {
            id     => 1,
            name   => "A",
            users  => [ { id => 1, name => "u1" },
                        { id => 2, name => "u2" } ],
            groups => [ { id => 1, name => "g1" } ],
           };

sub to_xml {
    my ($data, $xml) = @_;
    for my $entry (keys %$data) {
        my $ref = ref $data->{$entry};
        if (not $ref) {
            $xml->setAttribute($entry, $data->{$entry});

        } elsif ('ARRAY' eq $ref) {
            (my $name = $entry) =~ s/s$// or die "Can't guess the element name.\n";
            my $list = $xml->addNewChild(q(), $entry);
            for my $inner (@{ $data->{$entry} }) {
                to_xml($inner, $list->addNewChild(q(), $name));
            }

        } else {
            die "Unhandled structure $ref.\n";
        }
    }
}

my $xml = 'XML::LibXML::Document'->createDocument;
my $root = $xml->createElement('map');
$xml->setDocumentElement($root);
for my $entry ($data) {
    my $item = $root->addNewChild(q(), 'item');
    to_xml($entry, $item);
}

print $xml;

Answer 3

是的，明智的选择。 XML::Simple ... 不是。它是 for 简单的 XML。

正如 cmets 中所指出的 - 您的数据有点模棱两可 - 具体来说，您如何判断在“组”或“用户”中应该调用哪些元素。

看起来您可能已经解析了一些 JSON。 （确实可以直接转回JSON：

print to_json ( $data, { pretty => 1 } );

核心问题是 - JSON 支持数组，而 XML 不支持。因此，您几乎无法直接将您的数据结构转换为 XML。

但是，如果您不介意自己做一些工作：

以下是使用 XML::Twig 组装一些 XML 的方法

Assembling XML in Perl

use strict;
use warnings;

use XML::Twig;

my $twig = XML::Twig->new( 'pretty_print' => 'indented' );
$twig->set_root( 
    XML::Twig::Elt->new(
        'map',
    )
);
my $item = $twig->root->insert_new_elt('item', { 'id' => 1, 'name' => 'A' } );
my $users = $item ->insert_new_elt( 'users' );
   $users -> insert_new_elt ( 'user', { 'id' => 1, 'name' => 'u1' } );
   $users -> insert_new_elt ( 'user', { 'id' => 2, 'name' => 'u2' } );

my $groups = $item -> insert_new_elt ('last_child', 'groups');
   $groups -> insert_new_elt ( 'group', { 'id' => 1, 'name' => 'g1' } );

$twig->set_xml_version("1.0");
$twig->set_encoding('utf-8');

$twig->print;

哪些打印：

<?xml version="1.0" encoding="utf-8"?>
<map>
  <item id="1" name="A">
    <users>
      <user id="2" name="u2"/>
      <user id="1" name="u1"/>
    </users>
    <groups>
      <group id="1" name="g1"/>
    </groups>
  </item>
</map>

迭代您的数据结构留给读者作为练习。

正如 Borodin 正确指出的那样 - 您无法从数据结构中推断出 map item group 或 user。后两者你可以也许根据复数推断，但鉴于你的数据集，我能想到的最好的结果是这样的：

use strict;
use warnings;

use XML::Twig;

my $data = {
    id    => 1,
    name  => "A",
    users => [ { id => 1, name => "u1" }, { id => 2, name => "u2" } ],
    groups => [ { id => 1, name => "g1" } ]
};


my $twig = XML::Twig->new( 'pretty_print' => 'indented' );
$twig->set_root( XML::Twig::Elt->new( 'map', ) );

my $item = $twig->root->insert_new_elt('item');
foreach my $key ( keys %$data ) {
    if ( not ref $data->{$key} ) {
        $item->set_att( $key, $data->{$key} );
        next;
    }
    if ( ref( $data->{$key} ) eq "ARRAY" ) {
        my $fakearray = $item->insert_new_elt($key);
        foreach my $element ( @{ $data->{$key} } ) {
            my $name = $key;
               $name =~ s/s$//g;
            $fakearray->insert_new_elt( $name, $element );
        }
        next;
    }
    if ( ref ( $data -> {$key} ) eq "HASH" ) { 
        $item -> insert_new_elt( $key, $data -> {$key} );
        next;
    }
}

$twig->set_xml_version("1.0");
$twig->set_encoding('utf-8');

$twig->print;

这并不理想，因为 - map 是硬编码的，item 也是如此。我采用非常简单的方法，假设数组末尾有一个s，将其复数化。