如何从 Perl 脚本中删除除 shebang 行之外的所有注释？

Question

我有一个从其他 Perl 脚本中剥离 cmets 的 Perl 脚本：

open (INFILE, $file);
@data = <INFILE>;

foreach $data (@data)
{
    $data =~ s/#.*/ /g;
    print "$data";
}

问题是，这段代码还删除了 shebang 行：

#!/usr/bin/perl

除了shebang，我怎样才能剥离cmets？

Answer 1

编写代码来剥离 cmets 并非易事，因为# 字符可用于除 cmets 之外的其他上下文。请改用perltidy：

perltidy --delete-block-comments --delete-side-comments foo

将从文件foo 中删除# cmets（但不是POD）并将输出写入foo.tdy。 shebang 没有被剥离。

Answer 2

有一个方法PPR::decomment()可以使用：

use strict;
use warnings;
use PPR;

my $document = <<'EOF';
print "\n###################################\n";
print '\n###################################\n';
print '\nFollowed by comment \n'; # The comment
return $function && $function !~ /^[\s{}#]/;
EOF

my $res = PPR::decomment( $document );
print $res;

输出：

print "\n###################################\n";
print '\n###################################\n';
print '\nFollowed by comment \n'; 
return $function && $function !~ /^[\s{}#]/;

Answer 3

perltidy 是执行此操作的方法，如果它不是练习的话。还有PPI 用于解析perl。可以使用PPI::Token::Comment 令牌做一些比剥离更复杂的事情。

但是，要回答您的直接问题，请不要尝试在单个正则表达式中解决所有问题。相反，将您的问题分解为信息和逻辑的逻辑片段。相反，如果您想跳过第一行，请使用逐行处理来执行此操作，该处理可以方便地在$ 中设置当前行号。

use strict;
use warnings;
use autodie;

my $file = '... your file...';

open my $fh, '<', $file;

while (<$fh>) {
    if ($. != 1) {
        s/#.*//;
    }

    print;
}

免责声明

正如大家已经说过的那样，使用正则表达式解决这个问题的方法肯定是有缺陷的。但是，我要让您的讲师受益，并且她/他的目标是通过故意给您一个超出正则表达式能力范围的问题来进行教学。很好看，找到所有这些边缘情况并弄清楚如何处理它们。

无论您做什么，都不要尝试使用单个正则表达式来解决它们。分解你的问题并使用大量的if's 和elsif's

Answer 4

既然您要求使用正则表达式解决方案：

'' =~ /(?{
   system("perltidy", "--delete-block-comments", "--delete-side-comments", $file);
   die "Can't launch perltidy: $!\n"                   if $? == -1;
   die "perltidy killed by signal ".( $? & 0x7F )."\n" if $? & 0x7F;
   die "perltidy exited with error ".( $? >> 8 )."\n"  if $? >> 8;
});

---

您似乎倾向于使用以下内容：

#!/usr/bin/perl
while (<>) {
   if ($. != 1) {
      s/#.*//;
   }
   print;
}

但它对自己不起作用：

$ chmod u+x stripper.pl

$ stripper.pl stripper.pl >stripped_stripper.pl

$ chmod u+x stripped_stripper.pl

$ stripped_stripper.pl stripper.pl
Substitution pattern not terminated at ./stripped_stripper.pl line 4.

$ cat stripped_stripper.pl
#!/usr/bin/perl
while (<>) {
   if ($. != 1) {
      s/
   }
   print;
}

第一行删除cmets也失败：

$ cat >first.pl
# This is my first Perl program!
print "Hello, World!\n";

$ stripper.pl first.pl
# This is my first Perl program!
print "Hello, World!\n";