在 perl 哈希中计算字母的问题

Question

由于某些奇怪的原因，我遇到了小问题。我正在尝试计算每个字符串中的字母数量并带回最高数量。以下是该文件的示例。

@line =

------MMMMMMMMMMMMMMMMMMMMMMMMMM-M-MMMMMMMM  
------SSSSSSSSSSSSSSSSSSSSSSSSSS-S-SSSSSDTA  
------TIIIIIIIIIIIIITIIIVVIIIIII-I-IIIIITTT  

我尝试做的是对行中的每个单独元素进行计数的哈希，但由于某种原因，它不断为我提供每个单独氨基酸的计数。我希望输出是：

M 35
S 32
I 28

Answer 1

在您的代码中：

foreach my $aa ($string) {
    $counter{$aa}++;
}   

($string) 是一个由单个元素组成的列表，因此循环只运行一次，相当于$counter{ $string }++。

您需要遍历字符串中的单个字符。您可以通过使用@Miller 显示的空模式拆分字符串来做到这一点。但是，如果您的字符串很大，您将创建许多可能对性能有害的大型列表。另一种选择是依次匹配每个字符（您需要决定是否要匹配换行符、空格等）。

#!/usr/bin/env perl

use strict;
use warnings;

my @lines = qw(
    ------MMMMMMMMMMMMMMMMMMMMMMMMMM-M-MMMMMMMM
    ------SSSSSSSSSSSSSSSSSSSSSSSSSS-S-SSSSSDTA
    ------TIIIIIIIIIIIIITIIIVVIIIIII-I-IIIIITTT
);

for my $line ( @lines ) {
    my $x = argmax( count_characters($line) );
    print "@$x\n";
}

sub count_characters {
    my $string = shift;
    my %freq;
    while ($string =~ /(.)/g) {
        $freq{ $1 } += 1;
    }
    return \%freq;
}

sub argmax {
    my $freq = shift;
    my ($argmax, $max) = each %$freq;
    while (my ($k, $v) = each %$freq) {
        ($v > $max) and ($argmax, $max) = ($k, $v);
    }
    return [$argmax, $max];
}

输出：

M 35
小号 32
我 28 岁

Answer 2

您需要split 行来遍历字符：

use strict;
use warnings;

my %counter;

while (my $line = <DATA>) {
    chomp $line;

    for my $char (split '', $line) {
        $counter{$char}++;
    }
}

delete $counter{'-'};

while (my ($char, $count) = each %counter) {
    print "$char - $count\n";
}


__DATA__
------MMMMMMMMMMMMMMMMMMMMMMMMMM-M-MMMMMMMM
------SSSSSSSSSSSSSSSSSSSSSSSSSS-S-SSSSSDTA
------TIIIIIIIIIIIIITIIIVVIIIIII-I-IIIIITTT

输出：

A - 1
D - 1
M - 35
V - 2
I - 28
T - 6
S - 32