为什么排序与 uniq 不能一起工作

Question

我有以下脚本：

use strict;
use List::MoreUtils qw/uniq/;
use Data::Dumper;

my @x = (3,2);
my @y = (4,3);

print "unique results \n";
print Dumper([uniq(@x,@y)]);

print "sorted unique results\n";
print Dumper([sort uniq(@x,@y)]);

输出是

unique results 
$VAR1 = [
          3,
          2,
          4
        ];
sorted unique results
$VAR1 = [
          2,
          3,
          3,
          4
        ];

所以看起来 sort 不适用于 uniq。 我不明白为什么。

我用 -MO=Deparse 运行了 perl 脚本并得到了

use List::MoreUtils ('uniq');
use Data::Dumper;
use strict 'refs';
my(@x) = (3, 2);
my(@y) = (4, 3);
print "unique results \n";
print Dumper([uniq(@x, @y)]);
print "sorted unique results\n";
print Dumper([(sort uniq @x, @y)]);

我的解释是 perl 决定从 uniq(@x,@y) 中删除括号并使用 uniq 作为排序函数。

为什么 perl 决定这样做？

我怎样才能避免这些和类似的陷阱？

谢谢， 大卫

Answer 1

sort builtin 接受一个子例程名称或块作为第一个参数，该参数传递两个项目。然后它必须返回一个确定项目之间顺序的数字。这些 sn-ps 都是一样的：

use feature 'say';
my @letters = qw/a c a d b/;

say "== 1 ==";
say for sort @letters;

say "== 2 ==";
say for sort { $a cmp $b } @letters;

say "== 3 ==";
sub func1 { $a cmp $b }
say for sort func1 @letters;

say "== 4 ==";
sub func2 ($$) { $_[0] cmp $_[1] }  # special case for $$ prototype
say for sort func2 @letters;

注意函数名和列表之间没有逗号，注意 Perl 中的括号主要用于确定优先级——sort func1 @letters 和 sort func1 (@letters) 是相同的，两者都不执行 func1(@letters) .

要消除歧义，请在函数名称前添加 +：

sort +uniq @letters;

为避免此类意外行为，最好的解决方案是在您不确定某个内置函数的行为方式时阅读文档 - 不幸的是，许多都有一些特殊的解析规则。

Answer 2

你可以在 uniq 函数周围加上括号：

print Dumper([sort (uniq(@x,@y))]);

输出：

$VAR1 = [
          2,
          3,
          4
        ];