Perl 哈希在声明时引用自身

Question

在声明 Perl 哈希时，我想知道是否可以使用在声明之前分配的值。

我想一次性完成类似的操作：

my %H   = (something => generateString());
$H{foo} = $H{something} . "/FOO",
$H{bar} = $H{something} . "/BAR",

我可以想象这样的事情：

my %H = (
   something => generateString(),
   foo       => $_{something} . "/FOO",
   bar       => $_{something} . "/BAR",
);

编辑：需要明确的是，我不关心$H{something} 的实际引用（即稍后更改$H{something} 不应影响$H{foo}）。我只想将它的值放入字符串连接中。

Answer 1

您似乎认为

中有两个赋值运算符

%H = ( a=>1, b=>$H{a} );

没有。请记住，上述内容与

相同

%H = ( 'a', 1, 'b', $H{a} );

有一个赋值运算符，在你执行赋值之前，你需要知道什么是赋值。

我的意思是%H = ( a=>1, b=>$H{a} ); 的真正问题不是范围之一；真正的问题是，当您执行 $H{a}^[1] 时，没有任何内容分配给 %H。因此，$_{a} 比 $H{a} 更有意义。

解决方法很简单：

my $something = generateString();
my %H = (
   something => $something,
   foo       => "$something/FOO",
   bar       => "$something/BAR",
);

---

1. %H 还没有被创建！

Answer 2

my %H = (something => generateString());
%H = (%H, 
   foo => $H{something} ."/FOO",
   bar => $H{something} ."/BAR",
);

看起来很合理，但如果您想不惜一切代价一次性完成，

use strict;
use warnings;

%{ $_->{hash} } = (
   something => $_->{thing},
   foo       => "$_->{thing}/FOO",
   bar       => "$_->{thing}/BAR",
)
for {hash => \my %H, thing => generateString()};

可以翻译成更详细的版本，

my %H;
local $_ = {hash => \%H, thing => generateString()};

%{ $_->{hash} } = (
   something => $_->{thing},
   foo       => "$_->{thing}/FOO",
   bar       => "$_->{thing}/BAR",
);

Answer 3

正如 ikegami 所说，赋值操作只有一个；它在整个右侧被评估后执行。

几个选择：

my %H = map {;
    'something' => $_,
    'foo' => "$_/FOO",
    'bar' => "$_/BAR",
} generateString();

和

use Memoize;
memoize('generateString');
my %H = (
    'something' => scalar(generateString()),
    'foo' => generateString() . '/FOO',
    'bar' => generateString() . '/BAR',
);

（需要标量，否则，memoize 将对列表和标量上下文进行单独调用。）

Answer 4

另一种方法是将定义作为分配的一部分：

my %H = (
   something => ( local our $str=generateString() ),
   foo       => qq{$str/FOO},
   bar       => qq{$str/BAR}
);

有两点需要考虑：

1. 注意使用local our 而不是my
2. 我建议不要这样做。出于很多原因;如果不是为了最佳编码实践，而是为了可能引入的错误。

我觉得在哈希定义之外定义一个变量（如 Ikegami 的回答所示）是最好的方法，原因有很多，但我意识到这也不是被问到的问题。问题的答案是哈希在创建之前不能被引用，并且在创建期间它不会在构造函数中公开。