使用 Perl，我如何比较 YYYY-MM-DD 形式的日期？

Question

我有一个包含n 字符串的数组，格式为 YYYY-MM-DD（例如，“2010-10-31”）。

如何将日期与此数组中的字符串进行比较？

比如删除30天前的字符串？

Answer 1

YYYY-MM-DD 格式日期的优点在于您可以使用简单的字符串比较来比较它们。在 Perl 中，这就是 lt 和 gt 运算符。

在这种情况下，听起来您只是想检查数组中的日期是早于还是晚于给定的目标日期（恰好是“30 天前”）。对于这种情况，我将采取的方法是首先确定 30 天前的日期，然后将其作为字符串与数组中的每个日期进行比较。我不会介绍将所有 YYYY-MM-DD 字符串转换为“正确”日期对象、纪元时间等并返回的开销，只是为了测试代表较早的日期。

#!/usr/bin/env perl

use strict;
use warnings;

my $thirty_days = 30 * 24 * 60 * 60;
my ($old_day, $old_month, $old_year) = (localtime(time - $thirty_days))[3..5];
my $cutoff = sprintf('%04d-%02d-%02d', 
                     $old_year + 1900, $old_month + 1, $old_day);

my @dates = ('2010-10-12', '2010-09-12', '2010-08-12', '2010-09-13');
for my $date (@dates) {
  print "$date\n" if $date gt $cutoff;
} 

Answer 2

猜想有不止一种方法可以做到这一点，但我喜欢 Date::Simple 这样的东西..

文档中的示例：

use Date::Simple ('date', 'today');

# Difference in days between two dates:
$diff = date('2001-08-27') - date('1977-10-05');

# Offset $n days from now:
$date = today() + $n;
print "$date\n";  # uses ISO 8601 format (YYYY-MM-DD)

对对象进行算术运算非常棒 ++。

只有日期，没有小时、分钟或秒

Answer 3

use strict; use warnings;
use DateTime ();
use DateTime::Duration ();
use DateTime::Format::Natural ();

my $parser = DateTime::Format::Natural->new;
my $now    = DateTime->now;
my $delta  = DateTime::Duration->new( days => 30 );
my $cutoff = $now->subtract_duration( $delta );

my @new_dates = map  { $_->[1] }
                grep { -1 == $_->[0] }
                map  { 
                    chomp;
                    [
                        DateTime->compare(
                            $parser->parse_datetime( $_ ),
                            $cutoff
                        ),
                        $_ 
                    ]
                } <DATA>;

print "@new_dates";

__DATA__
2010-07-31
2010-08-31
2010-09-30
2010-10-31

Answer 4

一个好的开始是阅读The Many Dates of Perl 和DateTime 网站。

YYYY-MM-DD 格式是ISO 8601 日期表示形式。它的一些变体被认为是可以接受的，例如YYYY-MM-DD 和YYYYMMDD，甚至是旧数据中的YYMM。在选择比较这些日期的方法之前，您应该查看definitive list。

如果 ISO 8601 日期字符串是：1) 有效日期； 2) 格式相同，带或不带- 分隔符； 3) 缺少前导和尾随空格，一个有吸引力的特性是您可以通过简单的字典字符串比较对字符串进行排序或比较。

一般来说：

1. IFF 您不会检查日期是否有效并且 IFF 它们是相同的格式，并且 IFF 没有前导或尾随空格，您可以与另一个以相同格式表示目标日期的字符串进行比较。

--- 否则---

1. 决定一个 CPAN 模块来解析您的日期字符串（或自己匹配），

2. 如果您的日期在该范围内，则转换为纪元时间（或使用 CPAN 模块进行更大规模的日期/时间操作，如 Date::Manip 或 Date::Calc）

   李>

3. 对时间类型（纪元时间、绝对天数等）执行算术运算

4. 将时间转换回您想要的格式...

这是执行此操作的代码：

use warnings; use strict;
use Date::Calc qw/:all/;

my (@date_strings, @abs_days);

my $target=Date_to_Days(2010, 1, 15);

# set @date_string to "YYYY-MM-DAY" between some dates
for my $AbsDay(Date_to_Days(2009,1,1)..Date_to_Days(2011,12,31)) {
   my ($year, $mon, $day)=Add_Delta_Days(1,1,1,$AbsDay-1);
   my $s="$year-$mon-$day";
   push @date_strings, $s;
}

foreach my $s (@date_strings) {
    my ($year, $mon, $day);

    if(($year, $mon, $day)=$s=~/^(\d+)-(\d+)-(\d+)/) {
        my $days=Date_to_Days($year, $mon, $day);
        push @abs_days, $days 
             if ($target-$days <= 30 && $target-$days >= -30 );
    }
}

print "absolute day way:\n";
foreach my $days (@abs_days) {
    my ($year, $mon, $day)=Add_Delta_Days(1,1,1,$days-1);
    print "$year-$mon-$day\n";
}

Answer 5

你可以使用Time::ParseDate模块，

use strict;
use warning;
use Time::ParseDate;

my @dates = ('2010-10-12', '2010-09-14', '2010-08-12', '2010-09-13');
my @dates = 
  grep {parsedate($_, NO_RELATIVE => 1, UK => 1) > parsedate('-30 days') }@dates;   
 #output: 2010-10-12 2010-09-14

Answer 6

我是这样做的，有点冗长，但很容易理解并完成工作。 @out2 是一个二维数组，我正在使用 for 循环读取值。每个循环我都会将输入与@out2 进行比较，以查看它是更早还是更晚的时间/日期。如果是，那么我将值写入数组，然后比较下一个输入。

if ($year < $out2[$j][7]) {
  $lt = 1;
  goto JUMP;
}
if ($year > $out2[$j][7]) {
  $gt = 1;
  goto JUMP;
}
if ($month < $out2[$j][5]) {
  $lt = 1;
  goto JUMP;
}
if ($month > $out2[$j][5]) {
  $gt = 1;
  goto JUMP;
}
if ($day < $out2[$j][6]) {
  $lt = 1;
  goto JUMP;
}
if ($day > $out2[$j][6]) {
  $gt = 1;
  goto JUMP;
}
if ($time < $out2[$j][4]) {
  $lt = 1;
  goto JUMP;
}
if ($time > $out2[$j][4]) {
  $gt = 1;
  goto JUMP;
}

跳转：

if ($lt == 1) {
  $out2[$j][2] = "$dtime $month\/$day\/$year";
  $out2[$j][4] = $time;
  $out2[$j][5] = $month;
  $out2[$j][6] = $day;
  $out2[$j][7] = $year;
  $lt = 0;
  }

if ($gt == 1) {
  $out2[$j][3] = "$dtime $month\/$day\/$year";
  $out2[$j][4] = $time;
  $out2[$j][5] = $month;
  $out2[$j][6] = $day;
  $out2[$j][7] = $year;
  $gt = 0;
}

Answer 7

为什么不是 5.10 以来的 CORE Time::Piece 和 Time::Seconds，而不是 CPAN 搜索的前几个结果？

use strict;
use warnings;
use Time::Piece (); # we don't need to include overloaded locatime
use Time::Seconds;
use Data::Dumper;

my @dates = qw/2010-10-31 2012-10-16 2011-09-08/;

my $now = Time::Piece::localtime();

my @date_objects = map {
    Time::Piece->strptime( $_, '%F')  # %F is the same as %Y-%m-%d 
} @dates;

my @filtered_dates = grep {
    $now - $_ < (ONE_DAY * 30)
} @date_objects;

print Dumper(map($_->strftime('%F'), @filtered_dates));

Answer 8

在循环中查找最小日期：

var minDate = ...;
var maxDate = ...;

foreach my $date ( @$dates ) {
    if ($minDate gt $date){ # Less than.
        $minDate = $date; # Minimal date.
    }
    if ($minDate lt $date){ # Greater than.
        $minDate = $date; # Maxamal date.
    }
}