如何将变量数组存储在另一个数组中？

Question

我有一个关于将数组保存在另一个数组中的 perl 查询。之前有人问过一个相关问题（How do I add an array ref to the middle of an existing array in Perl?），但我找不到我的答案，所以我在这里发布。

我有 10 个文本文件，每个文件大约有 100 行文本。我想选择所有包含“重要”一词的行。执行此操作的脚本如下。我将所有包含单词“important”的行保存在一个数组中。所以，从每个文本文件中，我得到一个数组。我想将所有这些数组保存在另一个数组中？

my @list_of_files = ("input1.txt", "input2.txt","input3.txt"); my $list_of_files = @list_of_files;

for ($file=0, $file<$list_of_files; $files++){
 open INPUT_FILE, "$list_of_files[$file]" or die "can't open $file : $!";
 my @input = <INPUT_FILE>;
 my $size = @input;

 for ($num=0; $num<$size; $num++){
  if ($input[$num] =~ m/important/) {
   push (@sub_array, $output);
  }
 }
 close INPUT_FILE;
 push (@main_array, \@sub_array);   
}

@sub_array 的元素每次都会改变，那么，如何保留所有 sub_arrays 的元素？我希望最终输出为@main_array，其中包含3个元素，每个元素都是一个元素数组（包含“重要”一词的行）

非常感谢 TIA 的任何帮助

Answer 1

我的做法与 bvr 略有不同。但他的观点仍然成立。

# use qw() to define line with less punctuation
my @list_of_files = qw(input1.txt input2.txt input3.txt);

my @lines_in_file;

foreach my $file (@list_of_files) {
  open(my $in, '<', $file) or die "can't open $file : $!";

  # declare an array, not a scalar
  my @lines;

  # idiomatic use of while(<>) puts each record into $_
  while (<$in>) {
    # /../ works on $_ by default.
    # Postfix condition is more readable
    push @lines, $_ if /important/;
  }

  # Take reference to array and push it onto main array
  push @lines_in_file, \@lines;
}

Answer 2

我会这样解决你的问题：

my @list_of_files = ("input1.txt", "input2.txt", "input3.txt");

my @lines_in_file = ();                 # target array
for my $file (@list_of_files) {
    open(my $in,'<',$file) or die "can't open $file : $!";

    my $lines = [];                     # scalar containing arrayref for important lines
    while(my $input = <$in>) {
        if($input =~ /important/) {
            push @$lines, $input;       # push into arrayref
        }
    }
    close $in;

    push @lines_in_file, $lines;        # push arrayref into main array
}

注意事项：

• perl for 可以遍历数组，无需 C 样式 for 的麻烦
• 最好逐行处理文件，而不是将整个文件读入内存，尤其是基于行的处理
• [] 在每次迭代中构造新的 arrayref。如果你在每个循环中重复使用 @sub_array 并引用它，你最终会得到很多对同一事物的引用

Answer 3

如果您要时不时地用 Perl 编写一些东西，您将必须了解引用的工作原理以及如何构建复杂的数据结构。

作为 Perl 新手，我建议您访问 perldoc.perl.org、manuals section，并完成前三节课。只需大约一个半小时，您就会对如何解决您的问题和其他类似问题有一个想法。

tutorials 非常有用 - 简短实用。您将学习传递数据结构并对其进行迭代等等。

对于测试，请考虑使用Data::Dumper 和print Dumper($var) 轻松查看您复杂的数据结构。