无法使用 VBA 中的 ADODB 更新字段

Question

我的目标是能够从已关闭的工作簿中读取和写入单元格值。我使用 ADODB 来获取所需的信息。 文件是由公司网站生成的，所以在使用实际文件之前我无法更改内容。该文件为 Excel 格式。单元格中没有公式，只有值。 我想从工作表中获取日期、字符串、整数，但遇到了一些限制。

我编写了示例代码来向您展示发生了什么：

Dim rsConn As ADODB.Connection
Dim rsData As ADODB.Recordset
Dim strFileName As String
Dim strFieldNames As String
Dim intValue As Integer

strFileName = "C:\Tests\Sample.xlsx" ' Fullpath to a workbook
'strFieldNames = "CInt([Proj_Year]) as [Proj_Year]"
'strFieldNames = "[Proj_Year]"
strFieldNames = "*"

Set rsConn = New ADODB.Connection
With rsConn
    .ConnectionString = "Data Source=" & strFileName & "; Extended Properties=""Excel 12.0; HDR=YES; "";"
    .Provider = "Microsoft.ACE.OLEDB.12.0"
    .Open
End With

Set rsData = New ADODB.Recordset
With rsData
    .Source = "SELECT " & strFieldNames & " FROM A2:AE500;" ' Sheetname not required
    .ActiveConnection = rsConn
    '.CursorType = adOpenKeyset     ' Tried this - didn't work
    '.CursorType = adOpenDynamic     ' Tried this - didn't work
    .CursorType = adOpenStatic
    .LockType = adLockOptimistic
    .Open
End With

With rsData
    .MoveFirst
    Do While Not .EOF
        ' Getting the value
        intValue = .Fields(0).Value

        ' Make some crazy modifications of the value
        intValue = intValue + 10

        ' Updating
        .Fields(0).Value = intValue   ' this is place where crash happens

        ' Move to the next record
        .MoveNext
    Loop
End With

rsData.Close
Set rsData = Nothing
rsConn.Close
Set rsConn = Nothing

这是示例工作簿的屏幕截图：

我尝试了几种方法：

1. strFieldNames = "*" 我得到工作表中存在的所有列。但是驱动程序试图猜测字段类型，我不喜欢它，因为它的猜测是错误的。例如，单元格 I3 应该是字符串，但实际上它是 adDouble。所以阅读可能没问题，但我不能写回字符串。 我尝试使用IMEX=1，但没有帮助，尝试了MAXSCANROWS=1，Readonly=0，但也没有运气。我不想触摸 Windows 注册表来修改猜测行。

2. strFieldNames = "[Proj_Year]" 我只收到一列，但我遇到了与 1 中相同的限制。

3. strFieldNames = "CInt([Proj_Year]) as [Proj_Year]" 我收到所需类型的所需列。但是当我运行我收到的代码时：

无法更新字段

输入代码：.Fields(0).Value = intValue

在上面的代码中，我一次读取和写入一条记录。我尝试使用 GetRows 读取所有数据（30 列，3000 行），然后将数据数组解析到我自己的类中。读取所有数据后，我会修改此数据并将其一次写回工作表中的一条记录。

我需要做什么才能让这段代码正常工作？

Answer 1

我通常只使用Connection 对象的Execute 方法。

我的Before数据集（这是位于FilePath变量的文件中的数据）：

Field1  Field2
   1    a
   2    b
   3    c
   4    d
   5    e

我的之后数据集：

Field1  Field2
   1    b
   2    b
   3    c
   4    d
   5    e

这是对我有用的代码。

Const FilePath As String = "C:\Users\MyComputerName\Desktop\Book1.xlsx"
Const ConnStr As String = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & FilePath & _
                          ";Extended Properties='Excel 12.0 Xml;HDR=YES';"

Public Sub testUpdate()
    Dim conn As ADODB.Connection: Set conn = New ADODB.Connection

    With conn
        .connectionstring = ConnStr
        .Open
        .Execute "Update [Sheet1$] set Field2='b' where Field1=1"
    End With

    If conn.State = adopenstate Then conn.Close: Set conn = Nothing
End Sub

---

其他一些观察结果

• 这个strFileName = "C:\Tests\Sample.xlxs" 似乎不是一个有效的文件名。所以这可能会让你很伤心。
• 数据集的第一行不包含标题，因此以工作表名称[Sheet1$] 为例，我相信默认为F1,F2,F3 代表字段名称（F1 = Field1）。如果您想要两全其美，请使用 Sheet AND Range 限定范围，如下所示：[Sheet1$A1:B10]。请参阅here 了解更多详情。